 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi All,
I try to copy some POV sources to create a beam splitter, but irremediatly
it fails. The reflected laser beam goes in the wrong direction (and nothing
is transmitted). I join the code source.
Thanks in advance,
Cheers,
Jerome
-------------------------------------------------------------------------
#include "colors.inc"
global_settings {
max_trace_level 5
photons {
count 20000
autostop 10
media 100
jitter 0
}
}
camera {
orthographic
location <200, 200, 0>
look_at <0, 0, 100>
}
media {
scattering {0.5, color White extinction 0}
method 3
intervals 1 samples 4
}
light_source { <0,0,-400> Red
spotlight
point_at <0,0,400>
cylinder
parallel
radius 3.1 falloff 3.2
tightness 1
media_interaction on
}
light_source {<800, 800, 400>, color White
photons {refraction off reflection off}
media_interaction off
}
plane { y, -200
pigment {
checker color HuntersGreen color SummerSky
scale 50
scale <3, 1, 3>
}
finish {
ambient 0.2
diffuse 0.6
}
}
prism {
linear_spline
-25, 25, 3,
<-25,150>, <-25,100>, <25,150>
pigment{rgbt<0,0,0,1>}
finish {
ambient 0
diffuse 0
reflection 0.5
}
interior{ior 1.5}
photons{
target
reflection on
refraction on
collect on
}
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
If I understand you correct, yo want to reflect a laserbeam. To do this, you
have to use photons.
Look at 'POV-Ray for Windows v3.5/scenes/optics.pov' for an example.
Norbert
"Jerome" <etu### [at] free fr> schrieb im Newsbeitrag
news:web.3e042851f909ebf5ff8bc1340@news.povray.org...
> Hi All,
>
> I try to copy some POV sources to create a beam splitter, but irremediatly
> it fails. The reflected laser beam goes in the wrong direction (and
nothing
> is transmitted). I join the code source.
>
> Thanks in advance,
>
> Cheers,
>
> Jerome
>
> -------------------------------------------------------------------------
>
> #include "colors.inc"
>
>
> global_settings {
> max_trace_level 5
> photons {
> count 20000
> autostop 10
> media 100
> jitter 0
> }
> }
>
>
> camera {
> orthographic
> location <200, 200, 0>
> look_at <0, 0, 100>
> }
>
>
> media {
> scattering {0.5, color White extinction 0}
> method 3
> intervals 1 samples 4
> }
>
>
> light_source { <0,0,-400> Red
> spotlight
> point_at <0,0,400>
> cylinder
> parallel
> radius 3.1 falloff 3.2
> tightness 1
> media_interaction on
> }
>
>
> light_source {<800, 800, 400>, color White
> photons {refraction off reflection off}
> media_interaction off
> }
>
>
> plane { y, -200
> pigment {
> checker color HuntersGreen color SummerSky
> scale 50
> scale <3, 1, 3>
> }
> finish {
> ambient 0.2
> diffuse 0.6
> }
> }
>
>
>
> prism {
> linear_spline
> -25, 25, 3,
> <-25,150>, <-25,100>, <25,150>
> pigment{rgbt<0,0,0,1>}
> finish {
> ambient 0
> diffuse 0
> reflection 0.5
> }
> interior{ior 1.5}
> photons{
> target
> reflection on
> refraction on
> collect on
> }
> }
>
>
>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Norbert Kern <nor### [at] t-onlinede> wrote:
> If I understand you correct, yo want to reflect a laserbeam. To do this, you
> have to use photons.
Did you actually look at his source code (which you unnecesarily quoted
completely)?
--
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Sat, 21 Dec 2002 03:37:37 -0500, Jerome quoth:
> Hi All,
>
> I try to copy some POV sources to create a beam splitter, but
> irremediatly it fails. The reflected laser beam goes in the wrong
> direction (and nothing is transmitted). I join the code source.
Try something like the following. I added a transparent plane at y*24 and
moved the ground plane up to y*-25 to force POV-Ray to calculate the media
more accurately in the area where the laser beam is. I also added a box
to contain the media, since infinite media doesn't work properly with
photons (when you spread out 100 photons over the length of an infinitely
long ray, you aren't likely to see any of them). The apparent "goes the
wrong way" laser beam is simply a reflection of the portion of the beam
between the light source and the prism.
Right now the media photons are spaced fairly far apart. To fix this, you
can either increase the media photon count in the global_settings block
(which will slow the rendering down further), or make the box containing
the media smaller.
#include "colors.inc"
global_settings {
max_trace_level 5
photons {
spacing .1
autostop 10
media 100
jitter 0
}
}
camera {
orthographic
location <-200, 200, 0>
look_at <0, 0, 100>
}
box{<-1000,-26,-1000>,<1000,1000,1000> interior{
media {
scattering {0.5, color White extinction 0} method 3
intervals 1 samples 10
}
}
hollow
}
plane{y, 24 pigment{rgbt 1} hollow}
light_source { <0,0,-400> Red
spotlight
point_at <0,0,400>
cylinder
parallel
radius 3.1 falloff 3.2
tightness 1
media_interaction on
photons{reflection on refraction on}
}
light_source {<800, 800, 400>, color White
photons {refraction off reflection off} media_interaction off
}
plane { y, -25
pigment {
checker color HuntersGreen color SummerSky scale 50
scale <3, 1, 3>
}
finish {
ambient 0.2
diffuse 0.6
}
}
prism {
linear_spline
-25, 25, 3,
<-25,150>, <-25,100>, <25,150>
pigment{rgbt<0,0,0,1>}
finish {
ambient 0
diffuse 0
reflection 0.5
}
interior{ior 1.5}
photons{
target
reflection on
refraction on
collect on
}
}
//box{<150,-25,100>,<152,25,150> pigment{rgb 1}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
