isosurface
{
	function
	{f_sphere(x, y, z, 1.2)-f_noise3d(x, y, z)}
}
all i get is a box! whats going on!?!?!!!1adslkfj
I can't figure this out, what am I missing? help!

Post a reply to this message

Soace Munky wrote:
> isosurface
> {
>     function
>     {f_sphere(x, y, z, 1.2)-f_noise3d(x, y, z)}
> }
> all i get is a box! whats going on!?!?!!!1adslkfj
> I can't figure this out, what am I missing? help!

First: Watch your language.

Second: Here's some documentation for you to read:

http://www.povray.org/documentation/view/3.6.1/300/
http://www.povray.org/documentation/view/3.6.1/73/
http://www.povray.org/documentation/view/3.6.1/157/
http://www.povray.org/documentation/view/3.6.1/531/

Third: A modified version of your your code that renders ok:

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

#version 3.6;

#include "colors.inc"
#include "functions.inc"

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7
// The isosurface object. Note that less noise is added.

isosurface {
   function {
     f_sphere(x, y, z, 1.2) - 0.5*f_noise3d(x, y, z)
   }
   contained_by { sphere { <0, 0, 0>, 3 } }
   pigment { color White }
}

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7

light_source { <1, 1, -1>*100 color White }

camera {
   location -5*z
   look_at 0*y
}

background { color Blue*0.5 }

// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7


-- 
Tor Olav
http://subcube.net
http://subcube.com

Post a reply to this message

> isosurface
> {
>     function
>     {f_sphere(x, y, z, 1.2)-f_noise3d(x, y, z)}
> }
> all i get is a box! whats going on!?!?!!!1adslkfj
> I can't figure this out, what am I missing? help!

Your function define a isosurface which is more large than the default 
contained_by which is box { -1, 1 }. In fact, it is this box that you 
see. Try with contained_by { box { -2, 2 }}.

-- 
ZeSly
http://perso.wanadoo.fr/zesly/

Post a reply to this message

Soace Munky wrote:
> isosurface
> {
>     function
>     {f_sphere(x, y, z, 1.2)-f_noise3d(x, y, z)}
> }
> all i get is a box! whats going on!?!?!!!1adslkfj
> I can't figure this out, what am I missing? help!
so sorry for the stupid question...i missed the part where default is 
defined. i picked this up only a few days ago, imfairly new to this.
i figured it out...
im screwing around with media, trying to put bubbles of fog in muddy 
water, and i needed a shape for a more-or-less bubble of air.

Post a reply to this message

Soace Munky nous apporta ses lumieres ainsi en ce 2004-10-15 20:36... :

> Soace Munky wrote:
>
>> isosurface
>> {
>>     function
>>     {f_sphere(x, y, z, 1.2)-f_noise3d(x, y, z)}
>> }
>> all i get is a box! whats going on!?!?!!!1adslkfj
>> I can't figure this out, what am I missing? help!
>
> so sorry for the stupid question...i missed the part where default is 
> defined. i picked this up only a few days ago, imfairly new to this.
> i figured it out...
> im screwing around with media, trying to put bubbles of fog in muddy 
> water, and i needed a shape for a more-or-less bubble of air.

Relatively small bubles under the water surface are spherics. Those on 
the surface have the bottom side flatened, doable with a merge of a half 
sphere, a torus and a short sylinder.
Try this:
Have your water have the hollow attribute with an ior of 1.33. Use an 
union to place your underwater bubbles using an ior or 1, if using 
dispersion, use a value around 0.9.

Alain

Post a reply to this message