I'm trying to create a scene that'll eventually comprise a hollow (glass)
globe, with an emissive media inside it.

The file below is my minimal test to show the problem I can't solve - I've
created the hollow glass sphere, and inside that I've placed another sphere
with "transmit 1" which will eventually contain the media.  This is based on
the media example in the 3.6rc1 help files, and yes, I do know I'll need to
make both the spheres "hollow" to get the media working when I get that far.

Strangely, the interior sphere which is supposed to be completely invisible
shows up, but only when it's inside the hollow sphere.  If the hollow sphere
is removed from the scene then the inner sphere remains correctly invisible.

Am I just missing something stupid, or is what I'm trying to do impossible?


[NB: new to POVray, have messed around with ray tracers for many years]

cheers,

Ray

--8<--8<-- cut here --8<--8<--
#include "colors.inc"
#include "glass.inc"

global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0.0, 0.5, -4.0>
  look_at   <0.0, 0.0,  0.0>
}

light_source {
  <0, 0, 0>
  color rgb 1
  translate <-30, 30, -30>
}

sky_sphere {
  pigment { color rgb <0.7,0.7,1.0> }
}

plane {
  y, -1.001
  pigment { checker Red White rotate y*60 scale 2 }
}

/* a hollow glass sphere */
difference {
  sphere { 0.0, 1 }
  sphere { 0.0, 0.97 }
  texture { T_Glass1 }
  interior { I_Glass }
}

/* why can I see this sphere? */
sphere {
  0.0, 0.8
  pigment { rgbt 1 }
}
--8<--8<-- cut here --8<--8<--

Post a reply to this message

On Sat, 5 Jun 2004 23:23:17 +0100, "Ray Bellis"
<use### [at] raybellismeuk> wrote:

>Am I just missing something stupid, or is what I'm trying to do impossible?

All Media must be inside a hollow object to be visible. Create a
hollow box or sphere to contain your scene.


Regards
        Stephen

Post a reply to this message

> All Media must be inside a hollow object to be visible.
> Create a hollow box or sphere to contain your scene.

You've missed my point - there is *no* media in the test scene file!

It's simply a CSG sphere with a completely transmissive object inside it.
That object should be invisible, and is when it's outside the sphere.  But
put it inside the sphere, and it becomes visible...

Ray

Post a reply to this message

> It's simply a CSG sphere with a completely transmissive
> object inside it.  That object should be invisible, and
> is when it's outside the sphere.  But put it inside the
> sphere, and it becomes visible...

I've found the problem - it's the default "max_trace_level".

It seems that my scene needs a value of at least 7; amything less and the
inner sphere prevents the inbound rays from passing through to the back of
the hollow sphere and getting properly refracted.

Ray

Post a reply to this message

On Sun, 6 Jun 2004 09:35:47 +0100, "Ray Bellis"
<use### [at] raybellismeuk> wrote:

>You've missed my point - there is *no* media in the test scene file!

Opps! Sorry.

The problem is max_trace_level it needs to be set > 6 in your scene.
global_settings {
  assumed_gamma 1.0

  max_trace_level 7
}

Remember for media "hollow" is a keyword, not a difference. So maybe

/* a hollow glass sphere */
difference {
  sphere { 0.0, 1 }
  sphere { 0.0, 0.97 }   
  texture { T_Glass1 }
  interior { I_Glass }  
  hollow
}

/* why can I see this sphere?  */
sphere {
  0.0, 0.5
  pigment { rgbt 1 }     
  hollow  
}

as well. As your scene increases in complexity max_trace_level may
need to increase too.

Regards
        Stephen

Post a reply to this message

Stephen McAvoy <mca### [at] aolcom> wrote:
> All Media must be inside a hollow object to be visible. Create a
> hollow box or sphere to contain your scene.

  There are many misconceptions here.

  Firstly, you don't need to contain *your scene* into a hollow object
to use media. You just need to contain *the media itself* inside a
hollow object. If you have media inside an object and it's not showing
up, the reason is something else.

  Secondly, even that is not completely true: Global media (not contained
by anything) is possible.
  Global media works a bit like 'fog' but with the additional features of
media (such as the different types of media, the patterns and the
modifiers). However, some of the features will only be visible if the
ray hits an object, ie. has a finite length (an example of such feature
is a lightbeam through scattering media).

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

On 6 Jun 2004 07:46:11 -0400, Warp <war### [at] tagpovrayorg> wrote:

> There are many misconceptions here.

"Many"? many means, A large indefinite number:
http://dictionary.reference.com/search?q=many%20
A bit harsh coming from Mr Apostrophe :-}

>
>  Firstly, you don't need to contain *your scene* into a hollow object
>to use media. You just need to contain *the media itself* inside a
>hollow object.

Laziness on my part, sorry for perpetuating it.

>  Secondly, even that is not completely true: Global media (not contained
>by anything) is possible.
>  Global media works a bit like 'fog' but with the additional features of
>media (such as the different types of media, the patterns and the
>modifiers). However, some of the features will only be visible if the
>ray hits an object, ie. has a finite length (an example of such feature
>is a lightbeam through scattering media).

Didn't know that, It's not implemented in Moray AFAIK so I've never
used it.

Regards
        Stephen

Post a reply to this message

On Sat, 5 Jun 2004 23:23:17 +0100, "Ray Bellis"
<use### [at] raybellismeuk> wrote:


>Strangely, the interior sphere which is supposed to be completely invisible
>shows up, but only when it's inside the hollow sphere.  If the hollow sphere
>is removed from the scene then the inner sphere remains correctly invisible.
>


global_settings {
  assumed_gamma 1.0
  max_trace_level 8
}



-- 
to all the companies who wait until a large user base becomes
dependant on their freeware, then shafting said happy campers with
mandatory payment for continued usage. I spit on your grave.

Post a reply to this message