I have been playing around with POV-Ray for a while now. Nothing too
complex. Well, nothing complex at all really, i have trouble wrapping my
mind around the program and all of its code.

The sole reason im even learning this application is so i can duplicate a
wallpaper that was posted a few years ago in a computer forum, along with
its script. I really liked it, which is rare because i have a strange taste
in wallpapers. Recently i switched over to a dual monitor system, with
higher resolutions, and this old wallpaper just doesnt hold water anymore.
Its resolution is too low, and id prefer to stretch it over both screens.

I searched the forum it was posted on, but the thread it was posted in was
lost a long time ago during a crash. Posts trying to find the creator have
left me with no response and a feeling of desperation.

I was wondering if anyone here could help lead me in the direction of this
image. Im not looking for someone to do it for me, tho that would be
useful, im just trying to find a little assistance in understanding the
image and how it is composed. Perhaps examples of similar work would open
my eyes. I work much better with tweaking existing scripts than generating
them from scratch.

Here is a link to the image http://pics.velda.org/bg/Abstract/GrayDots.jpg

Any assistance is greatly appreciated. Thanks in advance.
-Velda

Post a reply to this message

Try
http://www.f-lohmueller.de/pov_tut/loop/povsi3e2.htm
Together with right colors and a bit of fog you should be on the right way.
Check out his whole site, there is much to learn. And the Insert-menu addons
are really useful.

Daniel

Post a reply to this message

"Velda" <Vel### [at] Veldaorg> wrote in message
news:web.3e1cf2eaf9fef28b847551d50@news.povray.org...


>
> Here is a link to the image http://pics.velda.org/bg/Abstract/GrayDots.jpg
>
> Any assistance is greatly appreciated. Thanks in advance.
> -Velda
>

Nice image, no idea who made it.

On the bright side, you've thrown a nice gauntlet down as to who can be the
first to recreate the scene.....

Post a reply to this message

Perhaps something like this?

camera
{ right x*image_width/image_height
  location <-.5,1.75,-4>*10
  look_at 0
  angle 55
}

background { rgb .4 }

light_source { <0,20,-10>, 1.5 fade_distance 12 fade_power 2 }

#declare Width = 120;
#declare Depth = 120;
#declare Height = .5;
#declare DotStep = .3;
#declare DotRadius = .11;
#declare Offset = <10,0,0>;

#declare Fxy = function(x,y) { sin(sqrt(x*x+y*y)+pi/2) }

union
{ #declare IndZ = 0;
  #while(IndZ <= Depth/DotStep)
    #declare Z = IndZ*DotStep-Depth/2;
    #declare IndX = 0;
    #while(IndX <= Width/DotStep)
      #declare X = IndX*DotStep-Width/2;

      sphere { <X, Fxy(X,Z)*Height, Z>+Offset, DotRadius }

      #declare IndX = IndX+1;
    #end
    #declare IndZ = IndZ+1;
  #end

  pigment { rgb .4 }
  finish { ambient 1 }
}


-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

If you are happy to work with meshes then there is a utility called
Elasticity that is made for the job. You can get it here.
http://www.flash.net/~drsledge/manual/manual.htm

Once you have a mesh you like you can then texture it. With a little
bit of work you can animate it and have moving wallpaper. 

Stephen

Post a reply to this message

On 9 Jan 2003 05:25:14 -0500 Warp wrote:

>  Perhaps something like this?

  Say, that's pretty darn close, Warp! :)

-- 
Alan
ako### [at] povrayorg
a k o n g <at> p o v r a y <dot> o r g

Post a reply to this message

On 9 Jan 2003 05:25:14 -0500
Warp <war### [at] tagpovrayorg> wrote:

>   Perhaps something like this?
> [...]

  That's very bad... I was finally cured from my addiction to render
explicit surfaces for wallpappers, and now you post such nice example!

  I'm now falling in an endless "change the formula and try again"
abyss... 

-- 
Jaime Vives Piqueres
		
La Persistencia de la Ignorancia
http://www.ignorancia.org

Post a reply to this message

"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3e1d414f$1@news.povray.org...
>
> On the bright side, you've thrown a nice gauntlet down as to who can be the
> first to recreate the scene.....
>

... which ain't gonna be me.

I've been playing with doing this as a single isosurface, but have run into a
problem I can't solve.

I can get a grid of spheres with:

#declare Fc = function(m){abs(int(m)*2-(int(m/2)*2)-m)}
#declare Fa = function(x,y,z){pow(Fc(x),2) + pow(y,2) + pow(Fc(z),2) - 1/2}

isosurface{
  function{Fa(x,y,z)}
  contained_by {box{<-10,-2,-10>,<10,2,10>}}
  accuracy 0.001
  max_gradient 10
  pigment{rgb 0.5}
}

but if I try and perturb their placement with:

#declare Fc = function(m){abs(int(m)*2-(int(m/2)*2)-m)}
#declare Fb = function(q,r){sin(pow(q,2)+pow(z,2))/5}
#declare Fa = function(x,y,z){pow(Fc(x),2) + pow(y-Fb(x,z),2) + pow(Fc(z),2) -
1/2}

isosurface{
  function{Fa(x,y,z)}
  contained_by {box{<-10,-2,-10>,<10,2,10>}}
  accuracy 0.001
  max_gradient 10
  pigment{rgb 0.5}
}

I run into the obvious problem of this affecting the sphere-shapes, rather than
their placement. I tried various INT options, so that Fb would return a constant
value for any particular sphere, but couldn't get it to work. Any ideas anyone?

Post a reply to this message

On Fri, 10 Jan 2003 15:14:33 +0100 Jaime Vives Piqueres wrote:

>  That's very bad... I was finally cured from my addiction to render
>explicit surfaces for wallpappers, and now you post such nice example!

  I changed Warp's scene to a nice shade of blue and it has replaced the
wallpaper I've been happy with for the past ~six months :)

-- 
Alan
ako### [at] povrayorg
a k o n g <at> p o v r a y <dot> o r g

Post a reply to this message