Francois wrote:

Change the <-8,0,-4>,<-8,8,4> to <-12,0,-4> <-9,0,4> and that should fix
it.

I write:

I changed the mistake to your suggestion, and there is still no cutout or
light.

Wade

Post a reply to this message

"Wade" <Zav### [at] aolcom> wrote in message
news:3ba0d08b$1@news.povray.org...
> Francois wrote:
>
> Change the <-8,0,-4>,<-8,8,4> to <-12,0,-4> <-9,0,4> and that should fix

the box here is degenerate as well (i.e. y1=y2=0) change second y back to 8
second, you still won't see the cutout because it is not in the scene, move
it back a bit

try <-12,0,-4> <-9,8,-8>

Post a reply to this message

"Trevor Quayle" <Tin### [at] hotmailcom> wrote in message
news:3ba0e4db$3@news.povray.org...


> try <-12,0,-4> <-9,8,-8>


it worked thanks Trevor, but how do I make the opening smaller?   I tried to
change the z coordinate in the 1st corner of the opening.  Here's my code:

#include "colors.inc"
#include "woods.inc"

#declare Wall_Texture=
texture{
 pigment{ color White-(White-Khaki)*0.495 }
 normal{ wrinkles 0.2 }
}

#declare light_wood=
pigment{ P_WoodGrain7A color_map {M_Wood7A} }
#declare dark_wood=
pigment{ P_WoodGrain14A color_map {M_Wood14A} }

#declare board_length= 1.5;
#declare board_width= 0.25;

#declare Floor_Texture=
texture{
 pigment{
  gradient y triangle_wave
  pigment_map{
   [ 0.0 light_wood]
   [ 1.0 dark_wood ]
  }
  warp{ repeat board_length*z offset 0.50*y }
  warp{ repeat board_width*x offset board_length*5/2*z }
 }
 normal{
  boxed
  slope_map{
   [0.5 <1.0, 0>]
   [1.0 <0, 0>]
  }
  bump_size 0.1
  scale <board_width,1,board_length>
  warp{ repeat board_length*z }
  warp{ repeat board_width*x offset board_length/2*z }
 }
}

light_source{
 <9,9,9>
 color White
 area_light
 <2,0,0> <0,0,2>
 8,8
 adaptive 0
 jitter
}

camera{
 location <0,5,11>
 look_at <0,5,-10>
}

// Right Wall
box{
 <10,0,-12>,<11,10,12>
 texture{
  Wall_Texture
 }
}

// Left Wall
difference{
 box{
  <-11,0,-12>,<-10,10,12>
  texture{
   Wall_Texture
  }
 }
 box{
  <-12,0,-1.5>,<-9,8,-8>
  texture{
   pigment{
    color White
   }
  }
 }
}

// Back Wall
box{
 <-10,0,-12>,<10,10,-13>
 texture{
  Wall_Texture
 }
}

// The Floor
box{
 <-10,-1,-12>,<10,0,12>
 texture{
  Floor_Texture
 }
}

// The Ceiling
box{
 <-10,10,-12>,<10,11,12>
 texture{
  Wall_Texture
 }
}

// A Round Table
union{
 cylinder { <0,0,0><0,0.1,0> 1.5 }
 cylinder { <0,0,0><0,1.4,0> 0.3 translate 0.1*y }
 cylinder { <0,0,0><0,0.1,0> 3 translate 1.5*y }
 texture { T_Wood1 }
 translate -7.25*z
}

Post a reply to this message

> // Left Wall
> difference{
>  box{
>   <-11,0,-12>,<-10,10,12>
>   texture{
>    Wall_Texture
>   }
>  }
>  box{
>   <-12,0,-1.5>,<-9,8,-8>
>   texture{
>    pigment{
>     color White
>    }
>   }
>  }
> }


the size of the cut out is the size of the box
i.e. box{<-12,0,-1.5>,<-9,8,-8>} is a cube 2 x 8 x 6.5
to make it smaller you have to change the coordinates in relation to each
other

i.e.  box{<-12,0,-6>,<-9,8,-8>} = 2x8x2
or    box{<-12,0,-1.5>,<-9,8,-3.5>} = 2x8x2

the only difference between these two is their location (corner at
<-12,0,-6> vs {<-12,0,-1.5>)

remember the vectors of the box represent the beginning and end points of
the cube not the size, the size is the difference between these points.

Post a reply to this message

Trevor Quayle wrote:
> 
> "Wade" <Zav### [at] aolcom> wrote in message
> news:3ba0d08b$1@news.povray.org...
> > Francois wrote:
> >
> > Change the <-8,0,-4>,<-8,8,4> to <-12,0,-4> <-9,0,4> and that should fix
> 
> the box here is degenerate as well (i.e. y1=y2=0)

Oops!  Sorry, I'd had 3 hours of sleep in the previous 40 when I wrote
that.

-- 
Francois Labreque | Unfortunately, there's no such thing as a snooze
    flabreque     | button on a cat who wants breakfast.
        @         |      - Unattributed quote from rec.humor.funny
   videotron.ca

Post a reply to this message

Wade wrote:
> 
> it worked thanks Trevor, but how do I make the opening smaller?   I tried to
> change the z coordinate in the 1st corner of the opening.  Here's my code:

The units in my modification of your code were feet.

If you want a realistic door,

use

>  box{
>   <-12,0,-5.5>,<-9,6.5,-8>

Doors over here are 30x78 inches.  Check with your local building codes
before attempting any major renovation work!

-- 
Francois Labreque | Unfortunately, there's no such thing as a snooze
    flabreque     | button on a cat who wants breakfast.
        @         |      - Unattributed quote from rec.humor.funny
   videotron.ca

Post a reply to this message