A comet's tail is actually composed of tiny particles or gases (blown off the
comet by the Solar wind, I think), so the tail effect isn't actually
motion-blur-from-movement (although it *looks* like that from a distance.) As
others mentioned, media might be a more appropriate way to create the tail;
perhaps media within a transparent cone object(?). Plus some turbulence.

However, your running-man example made me think of a 'solid media' idea,
something I posted years ago. It might be helpful, to get the effect you're
after. Take a look at the image example I posted there, a kind of step-by-step
guide...

http://news.povray.org/povray.binaries.images/message/%3Cweb.4436e54a72fe66658ad7a9060%40news.povray.org%3E/#%3Cweb.443

Post a reply to this message

On 26-5-2018 16:07, Kima wrote:
> There are some examples in this newsgroup for building a comet composed of a
> head and tail.
> 

In 2012 I built a scene of the Early Earth with meteor/comet showers. I 
looked up the code and found I used the following for building them:

//------------------------------------------------------------
#declare C_STAR = rgb <1.000, 0.477, 0.154>*1; //3000K
#declare fn_Disc = function (x) { 1 / (1 + pow (x, 3)) }
#declare fn_Spike = function (x) { 1 / (1 + pow (x, 2)) }

#declare Disc =
cylinder {0, y, 50
   hollow
   pigment {rgbt 1}
   interior {
     media {
       emission C_STAR * 10
       density {
         function {fn_Disc (sqrt (x*x + z*z))}
       }
     }
   }
}

#declare Diffraction_spike =
box {
   <-100, 0, -0.5>*4, <100, 1, 0.5>*4
   hollow
   pigment {rgbt 1}
   interior {
     media {
       emission C_STAR * 2
       density {
         function {fn_Spike (abs(x))}
       }
     }
   }
}

#declare Meteor_trail =
box {
   <0, -2, -2>*4, <10000, 2, 2>*4
   hollow
   pigment {rgbt 1}
   interior {
     media {
       emission C_STAR * 2
       density {
         function {fn_Spike (abs(x))}
       }
     }
   }
}

//---------------------------Meteor1
#declare star_pos = vaxis_rotate(SunPosition,x,10);
#declare star_pos = vaxis_rotate(star_pos,y,-170);
#declare YAxis = CamLoc - star_pos;

object {Disc
   scale 1800
   Point_At_Trans(YAxis)
   translate star_pos
}

object {Meteor_trail
   scale 1800
   rotate -100*y
   Point_At_Trans(YAxis)
   translate star_pos
}

object {Diffraction_spike
   scale 1200
   rotate 45*y
   Point_At_Trans(YAxis)
   translate star_pos
}

object {Diffraction_spike
   scale 1200
   rotate -45*y
   Point_At_Trans(YAxis)
   translate star_pos
}

//------------------------------------------------------------

A visualisation of this work canbe found here:
http://news.povray.org/povray.binaries.images/thread/%3C4ff1b4cc%40news.povray.org%3E/?ttop=422387&toff=1050

-- 
Thomas

Post a reply to this message