I'm trying to create an interesting starfield using a sky_sphere.  I considered
using stars.inc, but (and I think I've encountered this problem before) the
pre-defined starfield pigments are not what I expected.  They don't even look
like stars.

This is the best I've been able to come up with so far:

sky_sphere {
     pigment {
          granite
          color_map {
               [0.00 rgb 0.0]
               [0.80 rgb 0.0]
               [0.85 rgb 1.0]
               }
               scale 0.0001
          }
     }

I would like to add more color, and different size stars.  Perhaps some
clustering (might take a pigment_map).

Any help would be appreciated.

A.D.B.

Post a reply to this message

instead of granite, try something like this:

sky_sphere {
	pigment {
		crackle form <1,0,0>
		color_map {
			[0 rgb 5]
			[.1 rgbt 1]
		}
		scale .01
	}
}

imho it gives much better results.

cu!
-- 
ZK

Post a reply to this message

On 5/19/2011 12:00 AM, Zeger Knaepen wrote:
> instead of granite, try something like this:
>
> sky_sphere {
> pigment {
> crackle form <1,0,0>
> color_map {
> [0 rgb 5]
> [.1 rgbt 1]
> }
> scale .01
> }
> }
>
> imho it gives much better results.

Not always, IME. The crackle-form-x pattern, while producing circular 
points, often looks a little /too/ perfect.

I like good old granite myself, when used like so:

sky_sphere{
  pigment{
   granite
   scale 0.002/image_width
   poly_wave 28
   color_map{
    [0 rgb 0]
    [1 rgb 2]
   }
  }
}

The granite pattern tends to look more like star clusters. In my example 
it's been scaled according to the size of the render window, which helps 
a lot with these sorts of things (if it's not going to be animated, that 
is).

It's all a matter of preference, though :)

Sam

Post a reply to this message

On 5/19/2011 10:51 AM, stbenge wrote:
> On 5/19/2011 12:00 AM, Zeger Knaepen wrote:
>> instead of granite, try something like this:
>>
>> sky_sphere {
>> pigment {
>> crackle form <1,0,0>
...
>> }
>> }
>>
>> imho it gives much better results.
>
> Not always, IME. The crackle-form-x pattern, while producing circular
> points, often looks a little /too/ perfect.
>
> I like good old granite myself,

But then again, with the crackle-form-x pattern combined with a low 
metric value, you can do cool stuff like fake the appearance of glare at 
each star:

sky_sphere{
  pigment{
   crackle form x
   metric 0.35
   scale 0.002/image_width
   poly_wave 1/32
   color_map{
    [0 rgb 8]
    [1 rgb 0]
   }
  }
}

Sam

Post a reply to this message