I'm getting a lot of graphical artifacts when rendering the following scene.
The pigment appears speckled or mottled. I wasn't sure if this was a bug, or
if I was doing something wrong. I've tried it in 3.6.1 and the 3.7 beta with
no difference.

global_settings
{
 assumed_gamma 1.0
 radiosity
 {
  brightness 0.3
 }
}

background {rgb 1}

light_source
{
 <0, 0, 0>
 color rgb <1, 1, 1>
 translate <-30, 30, -30>
}

light_source
{
 <0, 0, 0>
 color rgb <1, 1, 1>
 translate <-30, 30, -30>
 rotate y * 90
}

camera
{
 location x*8
 direction 1.5*z
 right x*image_width/image_height
 look_at <0.0, 0.0,  0.0>
 rotate z*30
 rotate y*-65
}

sky_sphere
{
 pigment
 {
  gradient y
  color_map
  {
   [0.0 rgb <0.6,0.7,1.0>]
   [0.7 rgb <0.0,0.1,0.8>]
  }
 }
}

//------------------------------------------------------------------------------Pigments

#declare plane1P = pigment
{
 gradient x
 color_map
 {
  [0 rgb <0, 0, 0>]
  [1 rgb <1, 0, 0>]
 }
}

#declare plane2P = pigment
{
 gradient y
 color_map
 {
  [0 rgb <0, 0, 0>]
  [1 rgb <0, 1, 0>]
 }
}

#declare plane3P = pigment
{
 gradient z
 color_map
 {
  [0 rgb <0, 0, 0>]
  [1 rgb <0, 0, 1>]
 }
}


#declare averageP = pigment
{
 average
 pigment_map
 {
  [plane1P]
  [plane2P]
  [plane3P]
 }
 translate -x/2
 translate -y/2
 translate -z/2
 scale 2
}


//------------------------------------------------------------------------------CSG
objects

#declare sRadius = 1 ;
#declare sCenter = < 0 , 0 , 0 > ;

difference
{
 box
 {
  sRadius * -1, sRadius
 }
 box
 {
  sCenter, sRadius
  scale 1.00001
 }
 texture
 {
  averageP
  finish
  {
   ambient 1
  }
 }
 translate y * 0.001
}

Post a reply to this message

The gradient patterns change from a value of 1 to 0 right at the edge of
your object's surface. In some places, it's coming up with a value of 1, and
in others 0, causing speckling.

You can fix this by either using sRadius = 0.9999, or by adding "translate
.0001" within your texture{} block (as opposed to outside of the texture
block, where it is now).

 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message

"Slime" <fak### [at] emailaddress> wrote:
> The gradient patterns change from a value of 1 to 0 right at the edge of
> your object's surface. In some places, it's coming up with a value of 1, and
> in others 0, causing speckling.
>
> You can fix this by either using sRadius = 0.9999, or by adding "translate
> .0001" within your texture{} block (as opposed to outside of the texture
> block, where it is now).
>
>  - Slime
>  [ http://www.slimeland.com/ ]

Hey! That did the trick! Thanks!

Post a reply to this message