 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Anyone know where to find some good fire textures?
I'm trying to create a torch (kind of like you'd find in a dungeon),
and can't seem to find any good textures to use for the fire.
Also...any tips on animating the fire would be appreciated.
(i.e. getting the flame to MOVE with each frame)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
You can try with something like this:
--------8<------------8<------------8<------------8<-----------8<-------
// -w300 -h600 +a +kff50 +kc
#include "functions.inc"
camera { right x*30/60 location -z*7.5 look_at 0 angle 35 }
light_source { <10,20,-30>, .5 }
#declare TorchWood =
texture
{ pigment
{ wood color_map { [0 rgb <.7,.4,.2>][1 rgb <.9,.5,.3>] }
turbulence .5
}
normal
{ wood 1
turbulence .5
}
finish { specular .2 }
scale <.1,1,.1>
}
#declare SphericalF = function { pattern { spherical } }
#declare NoiseF =
function
{ (1-f_noise3d(x*5,y*5,z*5)*.9)*
(1-f_noise3d(x*15,y*15,z*15)*.4)
}
#declare Torch =
union
{ sphere
{ 0,1.2 hollow scale <1,2,1> translate y
pigment { rgbt 1 }
interior
{ media
{ emission .5
density
{ function
{ SphericalF(x,y,z)*
(NoiseF(x,y-clock*3,z)*(1-clock) +
NoiseF(x,y-clock*3+3,z)*clock)
}
density_map
{ [0 rgb 0]
[.2 rgb <.8,.4,0>]
[.21 rgb <1,1,.2>]
[.5 rgb <1,.9,.8>]
[1 rgb 1]
}
}
}
media
{ emission .5
density
{ function
{ SphericalF(x,y,z)*
(NoiseF(x,y*2-clock*3,z)*(1-clock) +
NoiseF(x,y*2-clock*3+3,z)*clock)
}
density_map
{ [0 rgb 0]
[1 rgb 1]
}
}
scale <1.2,2,1.2>
translate y*1.4
}
}
scale <1.5,3,1.5>
rotate z*-5
translate <.2,1.2,0>
}
cone { -y*4,.15, 0,.25 }
sphere { 0,.25 }
texture
{ pigment_pattern
{ gradient y color_map { [0 rgb 0][1 rgb 1] }
scale 4.25 translate -y*4
}
texture_map
{ [.7 TorchWood]
[.8 pigment { rgb 0 }]
[.9 pigment { rgb x*.8 } finish { ambient 1 }]
[1 pigment { rgb <1,.2,.2> } finish { ambient 1 }]
}
}
}
object { Torch translate -y*3 }
--------8<------------8<------------8<------------8<-----------8<-------
--
plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
<1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> --------8<------------8<------------8<------------8<-----------8<-------
Took me WAY too long to figure out what that is...
Man, I must be tired! I'll have to remember that one though...
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
MUCH appreciated!!!
thanks!
(now if I can just get that into Moray! hahaha)
"Warp" <war### [at] tag povrayorg> wrote in message
news:3f7744a1@news.povray.org...
> You can try with something like this:
>
> --------8<------------8<------------8<------------8<-----------8<-------
> // -w300 -h600 +a +kff50 +kc
>
> #include "functions.inc"
>
> camera { right x*30/60 location -z*7.5 look_at 0 angle 35 }
> light_source { <10,20,-30>, .5 }
>
> #declare TorchWood =
> texture
> { pigment
> { wood color_map { [0 rgb <.7,.4,.2>][1 rgb <.9,.5,.3>] }
> turbulence .5
> }
> normal
> { wood 1
> turbulence .5
> }
> finish { specular .2 }
> scale <.1,1,.1>
> }
>
> #declare SphericalF = function { pattern { spherical } }
> #declare NoiseF =
> function
> { (1-f_noise3d(x*5,y*5,z*5)*.9)*
> (1-f_noise3d(x*15,y*15,z*15)*.4)
> }
>
> #declare Torch =
> union
> { sphere
> { 0,1.2 hollow scale <1,2,1> translate y
> pigment { rgbt 1 }
> interior
> { media
> { emission .5
> density
> { function
> { SphericalF(x,y,z)*
> (NoiseF(x,y-clock*3,z)*(1-clock) +
> NoiseF(x,y-clock*3+3,z)*clock)
> }
> density_map
> { [0 rgb 0]
> [.2 rgb <.8,.4,0>]
> [.21 rgb <1,1,.2>]
> [.5 rgb <1,.9,.8>]
> [1 rgb 1]
> }
> }
> }
> media
> { emission .5
> density
> { function
> { SphericalF(x,y,z)*
> (NoiseF(x,y*2-clock*3,z)*(1-clock) +
> NoiseF(x,y*2-clock*3+3,z)*clock)
> }
> density_map
> { [0 rgb 0]
> [1 rgb 1]
> }
> }
> scale <1.2,2,1.2>
> translate y*1.4
> }
> }
> scale <1.5,3,1.5>
> rotate z*-5
> translate <.2,1.2,0>
> }
>
> cone { -y*4,.15, 0,.25 }
> sphere { 0,.25 }
> texture
> { pigment_pattern
> { gradient y color_map { [0 rgb 0][1 rgb 1] }
> scale 4.25 translate -y*4
> }
> texture_map
> { [.7 TorchWood]
> [.8 pigment { rgb 0 }]
> [.9 pigment { rgb x*.8 } finish { ambient 1 }]
> [1 pigment { rgb <1,.2,.2> } finish { ambient 1 }]
> }
> }
> }
>
> object { Torch translate -y*3 }
> --------8<------------8<------------8<------------8<-----------8<-------
>
> --
> plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
> sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
> density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
> <1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Okay.....maybe this is a different kind of question.
I took this texture definition, pretty much created the same thing
in Moray. When I preview the texture, it looks fine.
But when I actually assign it to a sphere, or cone, or something,
it doesn't show up at all.
Any clues?
"Warp" <war### [at] tagpovrayorg> wrote in message
news:3f7744a1@news.povray.org...
> You can try with something like this:
>
> --------8<------------8<------------8<------------8<-----------8<-------
> // -w300 -h600 +a +kff50 +kc
>
> #include "functions.inc"
>
> camera { right x*30/60 location -z*7.5 look_at 0 angle 35 }
> light_source { <10,20,-30>, .5 }
>
> #declare TorchWood =
> texture
> { pigment
> { wood color_map { [0 rgb <.7,.4,.2>][1 rgb <.9,.5,.3>] }
> turbulence .5
> }
> normal
> { wood 1
> turbulence .5
> }
> finish { specular .2 }
> scale <.1,1,.1>
> }
>
> #declare SphericalF = function { pattern { spherical } }
> #declare NoiseF =
> function
> { (1-f_noise3d(x*5,y*5,z*5)*.9)*
> (1-f_noise3d(x*15,y*15,z*15)*.4)
> }
>
> #declare Torch =
> union
> { sphere
> { 0,1.2 hollow scale <1,2,1> translate y
> pigment { rgbt 1 }
> interior
> { media
> { emission .5
> density
> { function
> { SphericalF(x,y,z)*
> (NoiseF(x,y-clock*3,z)*(1-clock) +
> NoiseF(x,y-clock*3+3,z)*clock)
> }
> density_map
> { [0 rgb 0]
> [.2 rgb <.8,.4,0>]
> [.21 rgb <1,1,.2>]
> [.5 rgb <1,.9,.8>]
> [1 rgb 1]
> }
> }
> }
> media
> { emission .5
> density
> { function
> { SphericalF(x,y,z)*
> (NoiseF(x,y*2-clock*3,z)*(1-clock) +
> NoiseF(x,y*2-clock*3+3,z)*clock)
> }
> density_map
> { [0 rgb 0]
> [1 rgb 1]
> }
> }
> scale <1.2,2,1.2>
> translate y*1.4
> }
> }
> scale <1.5,3,1.5>
> rotate z*-5
> translate <.2,1.2,0>
> }
>
> cone { -y*4,.15, 0,.25 }
> sphere { 0,.25 }
> texture
> { pigment_pattern
> { gradient y color_map { [0 rgb 0][1 rgb 1] }
> scale 4.25 translate -y*4
> }
> texture_map
> { [.7 TorchWood]
> [.8 pigment { rgb 0 }]
> [.9 pigment { rgb x*.8 } finish { ambient 1 }]
> [1 pigment { rgb <1,.2,.2> } finish { ambient 1 }]
> }
> }
> }
>
> object { Torch translate -y*3 }
> --------8<------------8<------------8<------------8<-----------8<-------
>
> --
> plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
> sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
> density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
> <1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
-s0da- <ske### [at] msncom> wrote:
> I took this texture definition, pretty much created the same thing
> in Moray. When I preview the texture, it looks fine.
The fire (and the smoke) is not a texture but a media which is defined
in the inside of the sphere (the texture in my code is just the wooden
texture of the torch).
That is, you can't use it as texture but you have to use it as media
inside a hollow sphere, as in my code.
Btw, the "smoke" is actually not smoke, but some light-emitting media.
You might need to change it to absorbing media or remove it completely.
--
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
3f774888@news.povray.org...
> MUCH appreciated!!!
>
> thanks!
>
> (now if I can just get that into Moray! hahaha)
>
There is Luis's "InsertCode" pluggin which allows you to insert any POV code
into a Moray scene
http://lightning.generator.tuxfamily.org/modules.php3?op=modload&name=Moray_
plugins&file=index
And I don't know if it works in Moray 3.3 or if it is a 3.5 feature but in
the material editor
create a new material, delete texture, select material, right click you can
find a direct code option
then type your code or right click in code window and paste formerly copied
code
HTH
Marc
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
3f77511c@news.povray.org...
> That is, you can't use it as texture but you have to use it as media
> inside a hollow sphere, as in my code.
>
Yes, as wrote Warp, the key word is "hollow"
in the modify tab of your sphere, check the hollow checkbox
Marc
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Mon, 29 Sep 2003 17:39:18 +0200, "Marc Jacquier" <jac### [at] wanadoofr>
wrote:
>And I don't know if it works in Moray 3.3 or if it is a 3.5 feature but in
>the material editor
Ver 3.5 :-{
Regards
Stephen
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
that's EXACTLY what I am looking for! Thanks a BUNCH!
"Marc Jacquier" <jac### [at] wanadoofr> wrote in message
news:3f7851d0$1@news.povray.org...
>
> 3f774888@news.povray.org...
> > MUCH appreciated!!!
> >
> > thanks!
> >
> > (now if I can just get that into Moray! hahaha)
> >
> There is Luis's "InsertCode" pluggin which allows you to insert any POV
code
> into a Moray scene
>
http://lightning.generator.tuxfamily.org/modules.php3?op=modload&name=Moray_
> plugins&file=index
>
> And I don't know if it works in Moray 3.3 or if it is a 3.5 feature but in
> the material editor
> create a new material, delete texture, select material, right click you
can
> find a direct code option
> then type your code or right click in code window and paste formerly
copied
> code
>
> HTH
> Marc
>
>
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
