![](/i/fill.gif) |
![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
From: Bill DeWitt
Subject: Model Bicycle? ( was Re: Bicycle model?)
Date: 14 Jul 2001 09:54:07
Message: <3b504eff@news.povray.org>
|
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Giving up on most of the available models I am attempting to model a
bicycle in MegaPov myself using isosurfaces for the frame. Unfortunately, my
idea about blobbing cylinders is not working too well, because when you
create a simple cylinder at an angle, it is somewhat flattened in one
direction.
Is there a good way to rotate a function in isosurfaces before you blob
it?
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
From: Bill DeWitt
Subject: Re: Model Bicycle? ( was Re: Bicycle model?)
Date: 14 Jul 2001 09:59:07
Message: <3b50502b@news.povray.org>
|
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Bill DeWitt" <bde### [at] cfl rr com> wrote in message
news:3b504eff@news.povray.org...
>
> Giving up on most of the available models I am attempting to model a
> bicycle in MegaPov myself using isosurfaces for the frame. Unfortunately,
my
> idea about blobbing cylinders is not working too well, because when you
> create a simple cylinder at an angle, it is somewhat flattened in one
> direction.
>
> Is there a good way to rotate a function in isosurfaces before you
blob
> it?
Sorry, here is what I am using now... I suspect I will need to make my
cylinders differently so that their end circles are tilted correctly.
#declare R = 0.25;
#declare C1 = function { x*x + z*z - R*R }
#declare C2 = function { y*y + z*z - R*R }
isosurface {
function { C1(x+y,y,z)
* C2(x,y,z)
- 0.001
}
method 1
accuracy 0.001
contained_by{sphere{0,3}}
pigment {rgb .9}
finish { ambient 0.25 }
}
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Bill DeWitt wrote:
>
> Giving up on most of the available models I am attempting to
> model a bicycle in MegaPov myself using isosurfaces for the frame.
> Unfortunately, my idea about blobbing cylinders is not working too
> well, because when you create a simple cylinder at an angle, it
> is somewhat flattened in one direction.
>
> Is there a good way to rotate a function in isosurfaces before
> you blob it?
Hello Bill,
Making the bicycle frame with an isosurface
is not an easy task, but the code below may
give you some hints.
(Note that I'm not sure if the possibility
to treat functions like I do below was
provided intentionally by the authors of
MegaPOV.)
Best regards,
--
Tor Olav Kristensen
mailto:tor### [at] hotmail com
http://hjem.sol.no/t-o-k
http://www.crosswinds.net/~tok
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
// Copyright 2001 by Tor Olav Kristensen
// mailto:tor### [at] hotmail com
// http://www.crosswinds.net/~tok
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
#version unofficial MegaPov 0.7;
#include "colors.inc"
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
#macro XYZrotFunction(Xrot, Yrot, Zrot)
function {
Object(
(x*cos(Zrot) - y*sin(Zrot))*cos(Yrot) + z*sin(Yrot),
(x*sin(Zrot) + y*cos(Zrot))*cos(Xrot) +
(( x*cos(Zrot) - y*sin(Zrot))*sin(Yrot) - z*cos(Yrot))*sin(Xrot),
(x*sin(Zrot) + y*cos(Zrot))*sin(Xrot) +
((-x*cos(Zrot) + y*sin(Zrot))*sin(Yrot) + z*cos(Yrot))*cos(Xrot)
)
}
#end // macro XrotFunction
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
#declare Sphere = function { sqrt(x^2 + y^2 + z^2) }
#declare RR = 0.25;
//#declare CylinderX = function { Sphere(0, y, z) - RR }
#declare CylinderY = function { Sphere(x, 0, z) - RR }
//#declare CylinderZ = function { Sphere(x, y, 0) - RR }
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
#declare Object = function { CylinderY(x, y, z) }
#declare A = pi/4;
#declare RotObject1 = XYZrotFunction(-A, 0, 0)
#declare RotObject2 = XYZrotFunction( 0, 0, 0)
#declare RotObject3 = XYZrotFunction( 0, 0, A)
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
#declare BlobbingFunction1 =
function {
RotObject1(x, y, z)*
RotObject2(x, y, z)*
RotObject3(x, y, z)
-0.001
}
/*
#declare Thr = 1/10000;
#declare BlobbingFunction2 =
function {
1
-Thr^RotObject1(x, y, z)
-Thr^RotObject2(x, y, z)
-Thr^RotObject3(x, y, z)
}
*/
isosurface {
function {
BlobbingFunction1(x, y, z)
}
method 2
max_gradient 10
// accuracy 0.001
contained_by { sphere { <0, 0, 0>, 3 } }
pigment { color White }
finish { ambient 0.25 }
}
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
light_source {
<10, 1, 0>*10
color White
shadowless
}
background { color Blue/2 }
camera {
location <2, 3, -3>*2
look_at <0, 0, 0>
}
// ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
From: Tom Melly
Subject: Re: Model Bicycle? ( was Re: Bicycle model?)
Date: 20 Jul 2001 11:57:36
Message: <3b5854f0@news.povray.org>
|
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Tor Olav Kristensen" <tor### [at] hotmail com> wrote in message
news:3B5853F6.7FDCDCAF@hotmail.com...
Just out of curiosity, what are all the
> // ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
things for?
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Tom Melly wrote:
>
> "Tor Olav Kristensen" <tor### [at] hotmail com> wrote in message
> news:3B5853F6.7FDCDCAF@hotmail.com...
>
> Just out of curiosity, what are all the
>
> > // ===== 1 ======= 3 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 =
>
> things for?
Those lines help me to see when I have reached 72 characters per line
and
thus when I should hit the return button. If I don't, the code will wrap
to
the next line if I post the code to this news server (at least for me
when
I'm viewing it)
--
Tor Olav Kristensen
mailto:tor### [at] hotmail com
http://hjem.sol.no/t-o-k
http://www.crosswinds.net/~tok
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Tor Olav Kristensen" <tor### [at] hotmail com> wrote :
>
> Making the bicycle frame with an isosurface
> is not an easy task, but the code below may
> give you some hints.
Yes, it did, thanks!
But... why don't -I- have MegaPOV 0.7? Last I heard 0.6 was the newest
version.
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
In article <3b5a24f6$1@news.povray.org>,
"Bill DeWitt" <bde### [at] cfl rr com> wrote:
> But... why don't -I- have MegaPOV 0.7? Last I heard 0.6 was the newest
> version.
Version 0.7 has been out since February 5...
--
Christopher James Huff - chr### [at] mac com, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tag povray org, http://tag.povray.org/
<><
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Don't you have an editor that takes care of this automatically?
External editors such as Vim and Emacs can do that easily,
Netscape's built-in editor, too.
--
Adrien Beau - adr### [at] free fr - http://adrien.beau.free.fr
Mes propos n'engagent que moi et en aucun cas mes employeurs
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Adrien Beau wrote:
>
> Don't you have an editor that takes care of this automatically?
> External editors such as Vim and Emacs can do that easily,
> Netscape's built-in editor, too.
Well, that works fine with text, but with code it might wrap where you
don't want it too, and it destroys indenting.
--
David Fontaine <dav### [at] faricy net> ICQ 55354965
My raytracing gallery: http://davidf.faricy.net/
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Adrien Beau wrote:
>
> Don't you have an editor that takes care of this automatically?
> External editors such as Vim and Emacs can do that easily,
> Netscape's built-in editor, too.
Hello Adrien.
I really love Emacs, but I'm POV-ing in a windows environment
these days (using POV-Ray for windows).
And therefore I use POV's integrated CodeMax editor, which
allows for far more than 72 characters on each line.
(I don't know if there's any way to limit it's line length.)
I also use those "lines" for separating the different sections
in my code, so I would insert several "separating lines" manually
anyway.
I could probably make a setup with a windows variant of Emacs
with a POV-mode, learn it some anti-line-wrapping tricks,
make it start POV-renderings when I hit e.g. a function key
and have it load the image into image viewer after the rendering.
But: I'm quite satisfied with the CodeMax editor so I probably
won't do this before I'm leaving MS Windows for a (L)Un(u)ix
environment.
--
Best regards,
Tor Olav
mailto:tor### [at] hotmail com
http://hjem.sol.no/t-o-k
http://www.crosswinds.net/~tok
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |