Hello,

is it possible to have an object that we only see when it is reflected ?
for example i have a mirror sphere and a sky_sphere with a gradient to
create a nice reflection on the sphere, but i want to keep a black
background. Any ideas ?

E

Post a reply to this message

Eric wrote:
> 
> Hello,
> 
> is it possible to have an object that we only see when it is reflected ?
> for example i have a mirror sphere and a sky_sphere with a gradient to
> create a nice reflection on the sphere, but i want to keep a black
> background. Any ideas ?
> 
> E

Instead of using a sky_sphere apply your pigment to a normal sphere of
the appropriate scale and then clip it with a plane so that the only
part of the sphere that is left is behind the camera.

-- 
Ken Tyler -  1200+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

In article <384E3B0C.44A128F6@pacbell.net>, lin### [at] povrayorg 
wrote:

> Instead of using a sky_sphere apply your pigment to a normal sphere of
> the appropriate scale and then clip it with a plane so that the only
> part of the sphere that is left is behind the camera.

Wouldn't it work to use a normal sphere for the sky, and have it bounded 
by an object identical to the mirror object? Something like:

#declare mirrorObject =
sphere {< 0, 0, 0>, 2.5 texture {mirrorTex}}

sphere {< 0, 0, 0>, 1//the "sky-sphere", an actual sphere
    texture {skyTex}
    scale 10000
    hollow//to avoid "camera in non-hollow object" warning
    bounded_by {object {mirrorObject}}
}

Note that you should set ambient to 1 for the sky texture, since you are 
no longer using the sky_sphere. The sky_sphere isn't an actual object, 
just a way of specifying the background with a pigment.

If I am wrong or have completely misunderstood the problem, blame it on 
early-morning caffeine deprivation. :-)

-- 
Chris Huff
e-mail: chr### [at] yahoocom
Web page: http://chrishuff.dhs.org/

Post a reply to this message

Eric <Eri### [at] u-clermont1fr> wrote:

> Hello,
> 
> is it possible to have an object that we only see when it is reflected ?
> for example i have a mirror sphere and a sky_sphere with a gradient to
> create a nice reflection on the sphere, but i want to keep a black
> background. Any ideas ?
> 

Well, it is quite easy when using the no_image patch currently available
in the Mac Unofficial MultiPatch.
For a windows version you will have to wait a little while when Nathan
releases his next update.

smellenbergh

//Here is a demo scene doing exactly what you ask for :-)
camera {
    location <0.0, 0.0, -5.5>
    angle 60
    look_at <0.0, 0.0, 0.0>
}

background { rgb  0 }
sphere {
    <0.0, 0.0, 0.0>, 5000
    texture {
        pigment {
            gradient <0.0, 1.0, 0.0>
            color_map {
                [ 0.000 rgbft <1.0, 0.5, 1.0, 0.0, 0.0> ]   //violet 1
                [ 0.100 rgbft <1.0, 0.5, 1.0, 0.0, 0.0> ]   //violet 2
                [ 0.214 rgbft <0.5, 0.5, 1.0, 0.0, 0.0> ]   //indigo
                [ 0.328 rgbft <0.2, 0.2, 1.0, 0.0, 0.0> ]   //blue
                [ 0.442 rgbft <0.2, 1.0, 1.0, 0.0, 0.0> ]   //cyan
                [ 0.556 rgbft <0.2, 1.0, 0.2, 0.0, 0.0> ]   //green
                [ 0.670 rgbft <1.0, 1.0, 0.2, 0.0, 0.0> ]   //yellow
                [ 0.784 rgbft <1.0, 0.5, 0.2, 0.0, 0.0> ]   //orange
                [ 0.900 rgbft <1.0, 0.2, 0.2, 0.0, 0.0> ]   //red1
                [ 1.000 rgbft <1.0, 0.2, 0.2, 0.0, 0.0> ]   //red2
            }
            scale <5000, 5000, 5000>
        }
        finish {
            ambient rgb <1.0, 1.0, 1.0>
        }
    }
    no_image    //comment this to show the reflected sky
    hollow
}
sphere {
    <0.0, 0.0, 0.0>, 2
    texture {
        pigment {
            rgb <1.0, 1.0, 1.0>
        }
        finish {
            reflection rgb <1.0, 1.0, 1.0>
            diffuse 0.0
        }
    }
}

 

-- 
e-mail:sme### [at] skynetbe

http://users.skynet.be/smellenbergh

Post a reply to this message