Ron Parker wrote:

> >Try a repeat warp on the pattern.
> 
> won't work.  The pattern he's talking about has roughly circular
> boundaries, and a repeat warp will put noticeable straight lines
> in the pattern.

I think I will stop posting suggestions for the rest of the week. Suggestion
burn out I suppose. Did anyone else just hear that crackling sound in my head ?

-- 
Ken Tyler

See my 850+ Povray and 3D Rendering and Raytracing Links at:
http://home.pacbell.net/tylereng/index.html

Post a reply to this message

On Tue, 31 Aug 1999 22:10:29 -0500, "John M. Dlugosz"
<joh### [at] dlugoszcom> wrote:

>I've seen metal plates and surfaces that are covered with polished circles,
>which I assume is due to being formed by a vertical milling machine.
>
>Any idea how I can do that with a texture in POV?
>
>--John
>

1. (easiest) Use a ripples normal along with Chris Colefax's texture
tiler macro 

2. (harder) Use an average of 10-20 randomly displaced (in the plane)
normals using the spherical pattern with a high frequency and a repeat
warp set up so that it does not intersect the pattern edges

3. (easy, Superpatch reuqired) Use an isosurface normal

4. (has its drawbacks) Rob a bank (you only need $3600) and then ask
Lance what to do :) "MAX.....3.0.... mumble.....mumble... yeah
kewl..... mumble ......anisotropic....mumble..... shading.....
nah...it's... cheap.....mumble....." etc, mumble <grin>


Peter Popov
ICQ: 15002700

Post a reply to this message

This could be done quite well with the crackle normal with a high frequency.
However, the crackle pattern in official POV will always give angular, rather
than circular features. I think the modified crackle pattern in the Superpatch
could produce almost exactly what you are looking for - if you're willing to
give it a try.
And whatever method you use, expect aliasing galore! My current background image
also imitates the milled metal effect. While I actually wanted the interference
patterns, it is probably not desirable in your case. Plus the render time was
HUGE.

Margus

"John M. Dlugosz" wrote:
> 
> I've seen metal plates and surfaces that are covered with polished circles,
> which I assume is due to being formed by a vertical milling machine.
> 
> Any idea how I can do that with a texture in POV?
> 
> --John

Post a reply to this message

Nieminen Juha wrote:
>Xplo Eristotle <inq### [at] unforgettablecom> wrote:
>: If I understand what you're referring to, I'm thinking that your best
>: chance at doing this is creating an image (with lots of little circles)
>
>  Why?
>  Circles can be easyly done with procedural textures.

If I understand what you're referring to, I think a regular onion or wood
should do it.

If you want the rings to be so thin that they aren't separately visible to
the eye you can just scale the normal large so that the normal pattern range
from 0 in the center to 1 at the edge. Average two of these normals. They
must be exactly the same except that the one should be inverted. If you use
this method you don't need large resolutions to get nice results.

Greetings,

Rune S. Johansen

---
Visit The RSJ Website at http://rsj.mobilixnet.dk
for 3D images including still lives, dragons,
mathematical shapes, and more. Stereograms,
tutorials, The POV Desktop Theme, hundreds of
raytracing jokes, miscellaneous other things,
and a lot of fun!

Post a reply to this message

/* 
On Thu, 02 Sep 1999 00:45:36 -0700, Ken wrote:
>
>
>Ron Parker wrote:
>
>> >Try a repeat warp on the pattern.
>> 
>> won't work.  The pattern he's talking about has roughly circular
>> boundaries, and a repeat warp will put noticeable straight lines
>> in the pattern.
>
>I think I will stop posting suggestions for the rest of the week. Suggestion
>burn out I suppose. Did anyone else just hear that crackling sound in my head ?

Looks like you were kinda right and I was kinda wrong.  I found a way to
use a repeat warp and not get any straight lines.  Render this scene.  Try
different values for Rings.  You are getting very sleepy...

John probably wants it as a normal, but that's relatively easy to accomplish.  
*/

#declare Rings=8;
                                      
#macro ScalesPigment( Map ) 
  #local Scale=pigment {wood color_map {Map} scale 2} pigment { wood 
  pigment_map {[1/sqrt(2) Scale scale .5/sqrt(2)][1/sqrt(2) Scale translate 1 
  scale .5/sqrt(2)]} scale sqrt(2) rotate 90*x warp {repeat z/2 flip z} warp 
  {repeat x/2 offset z/2}}
#end

#declare MyMap=color_map { 
  #declare i=0; 
  #while (i<=2*Rings-1) [i/(2*Rings-1) rgb mod(i,2)] #declare i=i+1; #end
}

camera {location 2 look_at 0}
plane {y,0 ScalesPigment( MyMap ) finish {ambient 1}}

Post a reply to this message

Nieminen Juha <war### [at] cctutfi> wrote in message
news:37ce27dc@news.povray.org...
>   I'm not sure if I understand at all what do you mean.
>   Do you mean something like this?

Not really... a single circle going on forever is easy.  The metal is
polished in one place making a swirl pattern, then polished in another spot,
and another, etc. so the surface is covered with lots of circles, not one
big one.

--John

Post a reply to this message

John M. Dlugosz <joh### [at] dlugoszcom> wrote:
: Not really... a single circle going on forever is easy.  The metal is
: polished in one place making a swirl pattern, then polished in another spot,
: and another, etc. so the surface is covered with lots of circles, not one
: big one.

  Perhaps something like this then:

#declare Distance=5;
#declare Circles=20;
camera { location <0,10,-10>*1.5 look_at 0 angle 35 }
light_source { <100,100,-100> 1 }
plane
{ y,0
  pigment { rgb x }
  finish { specular .5 }
  #declare CirclesNormal=
    normal
    { spherical 2 slope_map
      { [0 <0,0>]
        [.5 <1,2>]
        [.5 <1,-2>]
        [1 <0,0>]
      }
      frequency Circles
      scale Distance*sqrt(2)/2
    }
  normal
  { average normal_map
    { [1 CirclesNormal]
      [1 CirclesNormal translate x*Distance]
      [1 CirclesNormal translate -x*Distance]
      [1 CirclesNormal translate z*Distance]
      [1 CirclesNormal translate -z*Distance]
    }
    translate x*Distance/2
    warp { repeat x*Distance }
    translate -x*Distance/2
    translate z*Distance/2
    warp { repeat z*Distance }
    translate -z*Distance/2
  }
}


-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Try something like this for your slope_map if you have Superpatch:

crackle
form <1,0,0>
frequency BIG_NUMBER

You'll have to play around a bit, and use really high AA, but it might give you
what your looking for.

Post a reply to this message

"Kevin Wampler" wrote:
>Try something like this for your slope_map if you have Superpatch:
>
>crackle
>form <1,0,0>
>frequency BIG_NUMBER
>
>You'll have to play around a bit, and use really high AA, but it might give
you
>what your looking for.

I haven't tried it but this should work as well but with no need for high AA
at all.

normal {
   average
   normal_map {
      [crackle +1 form <1,0,0>]
      [crackle -1 form <1,0,0>]
   }
}

Greetings,

Rune S. Johansen

---
Visit The RSJ Website at http://rsj.mobilixnet.dk
for 3D images including still lives, dragons,
mathematical shapes, and more. Stereograms,
tutorials, The POV Desktop Theme, hundreds of
raytracing jokes, miscellaneous other things,
and a lot of fun!

Post a reply to this message

"John M. Dlugosz" wrote:

> I've seen metal plates and surfaces that are covered with polished circles,
> which I assume is due to being formed by a vertical milling machine.

> Any idea how I can do that with a texture in POV?

	Specular finish.

Post a reply to this message