Got these asteroid models from:

http://astronomy.swin.edu.au/%7Epbourke/terrain/asteroid2/

Only textured surfaces here, not like the kind described by Paul Bourke at:

http://astronomy.swin.edu.au/~pbourke/terrain/asteroid/

I was trying to render some kind of asteroid thing for temporary Windows 
wallpaper after finding these. Was looking for a model of Comet Tempel when 
I found them, for rendering a simple Deep Impact (the July 4th 
comet/projectile) collision scene. Began it by using isosurface and 
scattering media, except the isosurface was merely a random shape.

Anyway... This picture has the scales all wrong-- in a sense. Kleopatra is 
the largest, being 217 km long, and Eros is only 33 km. Instead of making 
them equal to each other I chose scale their sizes and move them closer or 
farther from the camera. Yes, it is supposed to be dark since asteroids 
would typically be dark to our eyes. I made the attempt to use relative 
brightnesses between all of them, too. Don't expect accuracy in any of it, 
only for fun.

Asteroid Ky26 is a speck of just about 30 meters, and it's also the darkest 
one. Golevka is the brightest, also small at only 350 meters. Both are shown 
4X closer than the bottom three. And Geographos is 5X farther away as them 
(Ky26, Golevka). Then, Eros is about 1.5X farther out than Geographos, and 
Kleopatra is around 20X beyond Eros. Confusing, sorry. It seemed the 
quickest way to get it rendered and still have some proper scaling.

Yeah, I know, they only look vaguely like space rocks. Thought I'd show how 
strange they can be if you aren't familiar with them already. Maybe I'll be 
able to make better cratered surfaces without resorting to image/bump maps 
someday but this isn't the day.

Thanks for looking!
Bob Hughes

Post a reply to this message

Attachments:
Download 'asteroids.jpg' (90 KB)

Preview of image 'asteroids.jpg'

I'm sure the shape-data is accurate as can be, but the texture
looks weird. I would not expect to vary between reddish/bluish
gray. Maybe more like 6489 Golevka (even though I'm sure it's
also the same texture), at least, as a global feeling.

Best,

        S.

-- 
Steven Pigeon, Ph. D.
ste### [at] videotronca
"Bob Hughes" <bob### [at] charternet> wrote in message 
news:42d91288@news.povray.org...
> Got these asteroid models from:
>
> http://astronomy.swin.edu.au/%7Epbourke/terrain/asteroid2/
>
> Only textured surfaces here, not like the kind described by Paul Bourke 
> at:
>
> http://astronomy.swin.edu.au/~pbourke/terrain/asteroid/
>
> I was trying to render some kind of asteroid thing for temporary Windows 
> wallpaper after finding these. Was looking for a model of Comet Tempel 
> when I found them, for rendering a simple Deep Impact (the July 4th 
> comet/projectile) collision scene. Began it by using isosurface and 
> scattering media, except the isosurface was merely a random shape.
>
> Anyway... This picture has the scales all wrong-- in a sense. Kleopatra is 
> the largest, being 217 km long, and Eros is only 33 km. Instead of making 
> them equal to each other I chose scale their sizes and move them closer or 
> farther from the camera. Yes, it is supposed to be dark since asteroids 
> would typically be dark to our eyes. I made the attempt to use relative 
> brightnesses between all of them, too. Don't expect accuracy in any of it, 
> only for fun.
>
> Asteroid Ky26 is a speck of just about 30 meters, and it's also the 
> darkest one. Golevka is the brightest, also small at only 350 meters. Both 
> are shown 4X closer than the bottom three. And Geographos is 5X farther 
> away as them (Ky26, Golevka). Then, Eros is about 1.5X farther out than 
> Geographos, and Kleopatra is around 20X beyond Eros. Confusing, sorry. It 
> seemed the quickest way to get it rendered and still have some proper 
> scaling.
>
> Yeah, I know, they only look vaguely like space rocks. Thought I'd show 
> how strange they can be if you aren't familiar with them already. Maybe 
> I'll be able to make better cratered surfaces without resorting to 
> image/bump maps someday but this isn't the day.
>
> Thanks for looking!
> Bob Hughes
>
>
>

Post a reply to this message

"Steven Pigeon" <ste### [at] videotronca> wrote in message 
news:42d974e4$1@news.povray.org...
> I'm sure the shape-data is accurate as can be, but the texture
> looks weird. I would not expect to vary between reddish/bluish
> gray. Maybe more like 6489 Golevka (even though I'm sure it's
> also the same texture), at least, as a global feeling.

Thanks for the comments Steven.

Yes, intermediate-sized ones look better to me too. Eros and Kleopatra have 
one more layer of crackle pigment and normal added to them to use two 
different sizes of craters. Or at least what is supposed to be craters. I 
muted the colors a lot since the first renderings I did. I was trying for 
something like the Galileo spacecraft photos of Gaspra and Ida, as seen in 
the color pictures at:

http://nssdc.gsfc.nasa.gov/photo_gallery/photogallery-asteroids.html

I think most people think of asteroids as being only grey or a grey-brown, 
grey-blue. I'm not sure how realistic any of the photos are of those I've 
seen but I still can't get it to look right. I believe all are over-exposed.

Bob Hughes

Post a reply to this message

Bob Hughes wrote:

Nice texturing.


 > Yeah, I know, they only look vaguely like space rocks. Thought I'd 
show how strange they can be if you aren't familiar with them already. 
Maybe I'll be able to make better cratered surfaces without resorting to 
image/bump maps someday but this isn't the day.
 >

An idea for some Q&D craters

#local S = seed(1234);
#local DensityCurve =
spline {
    0/2 <0,0,0>
    1/2 <.5,.15,0>
    2/2 <1,1,0>
};
#local PN =
pigment {
    average
    pigment_map {

       #local I=0;#while(I<256)
           #local ScaleFactor = DensityCurve(rand(S)).y;
           [1
               cylindrical
               scale  .15*ScaleFactor
               #local ScaleFactor =  .5*ScaleFactor;
               poly_wave .8
               pigment_map {
                       [0 rgb   .1]
                       [.1 rgb  10*(1-ScaleFactor)]
                       [.2 rgb -20*(1-ScaleFactor)]
                       [1 rgb  -30*(1-ScaleFactor)]
               }
               rotate <rand(S)*180,rand(S)*180,rand(S)*180>
           ]
       #local I=I+1;#end
    }
};
sphere {
    0, 2
    pigment { rgb .6 }
    normal {
       pigment_pattern {
          average
          pigment_map {
             #local Scl  = 1;
             #local I=0;#while(I<12)
                     [1
                         PN
                         scale Scl
                         rotate <rand(S)*180,rand(S)*180,rand(S)*180>
                     ]
                     #local Scl=Scl*.8;
             #local I=I+1;#end
          }
       }
       bump_size 15
    }
}

Post a reply to this message

Attachments:
Download 'img.00062.jpg' (38 KB)

Preview of image 'img.00062.jpg'

"Jim Charter" <jrc### [at] msncom> wrote in message 
news:42da0c99@news.povray.org...
> Bob Hughes wrote:
>
> Nice texturing.

Thanks Jim, only a simple layered texture though. It's crackle form 
<1.25,0,0.25>, which was just trial and error to get. Here it is, with 
different finish statements and lowest layer (minus uppermost layer, too).

camera {
  location  <0, 0, -3>
  look_at   <0, 0, 0>
}

light_source {
 <100,100,-100>, 1
}

sphere {
  0, 1
  texture {
   pigment {
    color rgb 0.5
   }
  }
 texture {
  pigment {
   crackle form <1.25,0,0.25> scallop_wave turbulence 0.1 scale 0.1
   color_map {
    [0 color rgbf <0.7,0.65,0.625,1>]
    [0.3 color rgbf <0.55,0.525,0.5,1>]
    [0.7 color rgbf <0.45,0.5,0.5,1>]
    [1 color rgbf <0.425,0.425,0.45,1>]
   }
  }
  normal {
   crackle -0.7 form <1.25,0,0.25> scallop_wave turbulence 0.1 scale 0.1
  }
  finish {
   specular 0.1 roughness 0.01
  }
 }
 texture {
  pigment {
   crackle form <1.25,0,0.25> scallop_wave turbulence 0.125 scale 0.033
   color_map {
    [0 color rgbt <0.7,0.65,0.625,0.9>]
    [0.3 color rgbt <0.55,0.525,0.5,0.9>]
    [0.7 color rgbt <0.45,0.5,0.5,0.9>]
    [1 color rgbt <0.425,0.425,0.45,0.9>]
   }
  }
  normal {
   crackle -0.85 form <1.25,0,0.25> scallop_wave turbulence 0.125 scale 
0.033
  }
  finish {
   specular 0.1 roughness 0.01
  }
 }
}

I'm looking yours over now, trying to understand it.

Clever thing... although, I am finding it to be very slow to render. Since 
you used 'average' I'm trying that with the layered crackle patterns now and 
it looks better that way.

Should be able to create an isosurface with real surface variations instead 
of faking it with a normal; unfortunately, the asteroid mesh models made 
that impossible.

You might want to rethink the "Q&D" and say S&C (slow and clean). Only 
joking.

> An idea for some Q&D craters
>
> #local S = seed(1234);
> #local DensityCurve =
> spline {
>    0/2 <0,0,0>
>    1/2 <.5,.15,0>
>    2/2 <1,1,0>
> };
> #local PN =
> pigment {
>    average
>    pigment_map {
>
>       #local I=0;#while(I<256)
>           #local ScaleFactor = DensityCurve(rand(S)).y;
>           [1
>               cylindrical
>               scale  .15*ScaleFactor
>               #local ScaleFactor =  .5*ScaleFactor;
>               poly_wave .8
>               pigment_map {
>                       [0 rgb   .1]
>                       [.1 rgb  10*(1-ScaleFactor)]
>                       [.2 rgb -20*(1-ScaleFactor)]
>                       [1 rgb  -30*(1-ScaleFactor)]
>               }
>               rotate <rand(S)*180,rand(S)*180,rand(S)*180>
>           ]
>       #local I=I+1;#end
>    }
> };
> sphere {
>    0, 2
>    pigment { rgb .6 }
>    normal {
>       pigment_pattern {
>          average
>          pigment_map {
>             #local Scl  = 1;
>             #local I=0;#while(I<12)
>                     [1
>                         PN
>                         scale Scl
>                         rotate <rand(S)*180,rand(S)*180,rand(S)*180>
>                     ]
>                     #local Scl=Scl*.8;
>             #local I=I+1;#end
>          }
>       }
>       bump_size 15
>    }
> }

Post a reply to this message

Bob Hughes wrote:

> I'm looking yours over now, trying to understand it.
> 
> Clever thing... although, I am finding it to be very slow to render. Since 
> you used 'average' I'm trying that with the layered crackle patterns now and 
> it looks better that way.
> 

> You might want to rethink the "Q&D" and say S&C (slow and clean). Only 
> joking.
> 
> 
LOL!
Yes it is very slow. Agreed.

In the code the, ScalingFactor is just an attempt to produce more little 
ones than big ones, and at the same time make the little ones inverse 
proportionately deeper.

Defining the pigment beforehand is just an attempt to get around the 
limit of 256 terms to be averaged.

Also I think it looks better, or at least closer to your example, with 
poly_wave set between 1 and 4.

The crater profile is mostly about the pigment_map of course

Otherwise just a bunch of averaged cylindricals rotated and scaled randomly.

Yes Slow. My example rendered -aa in about 5 minutes.

That you would use the idea or something similar to augment your texture 
was what I was thinking.  With a little less random, but rather more 
judicious application, you might get faster times and better effects.

Post a reply to this message

"Jim Charter" <jrc### [at] msncom> wrote in message 
news:42da75dc$1@news.povray.org...
>
> Also I think it looks better, or at least closer to your example, with
> poly_wave set between 1 and 4.

I've tried it with poly_wave 1.8 and I see what you are saying about that.

> Yes Slow. My example rendered -aa in about 5 minutes.

It isn't slow enough to matter, I guess, if doing mainly a cratered 
planetoid anyway. In fact, I've tried it with 50 iterations for the first 
loop and 25 for the second and using default AA it was 3 minutes 50 seconds 
(on a 2GHz CPU here) to do the attached image.

> That you would use the idea or something similar to augment your texture
> was what I was thinking.  With a little less random, but rather more
> judicious application, you might get faster times and better effects.

I changed the average value to be rand(S), too, so it could have old and 
young craters mixed together. I'm thinking that to use this appropriately on 
irregular shapes, like those asteroids, it might be a good idea to try and 
match the surface normal using trace in some way. Something to think about 
anyhow, not sure I'll ever get around to it though.

Thanks a bunch for sharing this other way Jim.

Bob Hughes

Post a reply to this message

Attachments:
Download 'jccratersrandomaverage.jpg' (14 KB)

Preview of image 'jccratersrandomaverage.jpg'

I've always preferred using an inverted granite pattern for a more 
natural looking heavily cratered surface, though it doesn't give any 
distinct individual craters, so maybe you could combine the two 
techniques. Anyway here's a quick example (this is the entire source file!):

//moon
light_source { <-1,1,-1>*1000, rgb 1 }

sphere {
	z*3, 1
	pigment { rgb 1 }
	finish { diffuse 1 ambient 0 }
	normal {
		pigment_pattern { granite } -.2
		accuracy 1/5000
	}
}


Tek


Bob Hughes wrote:
> "Jim Charter" <jrc### [at] msncom> wrote in message 
> news:42da75dc$1@news.povray.org...
> 
>>Also I think it looks better, or at least closer to your example, with
>>poly_wave set between 1 and 4.
> 
> 
> I've tried it with poly_wave 1.8 and I see what you are saying about that.
> 
> 
>>Yes Slow. My example rendered -aa in about 5 minutes.
> 
> 
> It isn't slow enough to matter, I guess, if doing mainly a cratered 
> planetoid anyway. In fact, I've tried it with 50 iterations for the first 
> loop and 25 for the second and using default AA it was 3 minutes 50 seconds 
> (on a 2GHz CPU here) to do the attached image.
> 
> 
>>That you would use the idea or something similar to augment your texture
>>was what I was thinking.  With a little less random, but rather more
>>judicious application, you might get faster times and better effects.
> 
> 
> I changed the average value to be rand(S), too, so it could have old and 
> young craters mixed together. I'm thinking that to use this appropriately on 
> irregular shapes, like those asteroids, it might be a good idea to try and 
> match the surface normal using trace in some way. Something to think about 
> anyhow, not sure I'll ever get around to it though.
> 
> Thanks a bunch for sharing this other way Jim.
> 
> Bob Hughes
> 
> 
>

Post a reply to this message

Attachments:
Download 'moon.jpg' (39 KB)

Preview of image 'moon.jpg'

Bob Hughes wrote:
>
  I'm thinking that to use this appropriately on
> irregular shapes, like those asteroids, it might be a good idea to try and 
> match the surface normal using trace in some way. Something to think about 
> anyhow, not sure I'll ever get around to it though.
> 

You also have normal data from the original mesh too? Either natively or 
as cross products of the verts? Though a shotgun trace would probably be 
easier.  Then again maybe use a few normals from the mesh as seeds then 
cluster some traces around them?  It also occurred to me that using 
local clusters  you could avoid the Venn Diagram looking situations by 
somehow creating nested patterns instead of averaged...maybe by writing 
to an include file?

Post a reply to this message

"Tek" <tek### [at] evilsuperbraincom> wrote in message 
news:42dabb42@news.povray.org...
> I've always preferred using an inverted granite pattern---8<---
>
> //moon
> light_source { <-1,1,-1>*1000, rgb 1 }
>
> sphere {
> z*3, 1
> pigment { rgb 1 }
> finish { diffuse 1 ambient 0 }
> normal {
> pigment_pattern { granite } -.2
> accuracy 1/5000
> }
> }

Hadn't seen it done that way before.

I did use a small scale negative granite normal on the topmost layer, it 
just isn't very obvious. I realize now I overlooked adding a no_bump_scale 
keyword to prevent the depth from scaling after applying it to the 
asteroids, which were then scaled. Of course that meant readjusting the 
normals.

Attaching the changed (rescaled textures) image here.

Post a reply to this message

Attachments:
Download '8asteroids.jpg' (124 KB)

Preview of image '8asteroids.jpg'