POV-Ray : Newsgroups : povray.binaries.images : Parabolic mirror 2 Server Time: 26 Oct 2020 13:43:07 GMT
  Parabolic mirror 2 (Message 1 to 9 of 9)  
From: Warp
Subject: Parabolic mirror 2
Date: 15 May 2005 17:52:06
Message: <42878c45@news.povray.org>
A smaller section of the parabola now.

  This beautifully demonstrates *why* parabolic antennas have to be
perfectly aligned to work properly.


Post a reply to this message


Attachments:
Download 'ParabolicMirror3.jpg' (64 KB)
Download 'ParabolicMirror4.jpg' (68 KB)

Preview of image 'ParabolicMirror3.jpg'
ParabolicMirror3.jpg

Preview of image 'ParabolicMirror4.jpg'
ParabolicMirror4.jpg


 

From: Jaap
Subject: Re: Parabolic mirror 2
Date: 16 May 2005 13:45:01
Message: <web.4288a34b408416d1a8399d8d0@news.povray.org>
very nice.

is anybody else seeing black dots
flashing at the beam crossings?

reminds me of the first time i used pov:
for testing methods for projecting a thin
line of light using a row or LED's and a
cylindrical lens.

jaap.


Post a reply to this message


Attachments:
Download 'leds.png' (18 KB)

Preview of image 'leds.png'
leds.png


 

From: Mike Raiford
Subject: Re: Parabolic mirror 2
Date: 16 May 2005 13:50:20
Message: <4288a51c$1@news.povray.org>
Jaap wrote:
> very nice.
> 
> is anybody else seeing black dots
> flashing at the beam crossings?

Ooh, the image is just rife with optical illusions.

The two horizontal beams adjoining the focal point appear curved, and 
the effect you just pointed out.

-- 
~Mike

Things! Billions of them!


Post a reply to this message

From: Cousin Ricky
Subject: Re: Parabolic mirror 2
Date: 17 May 2005 00:30:00
Message: <web.42893a00408416d1755fa2580@news.povray.org>
Warp <war### [at] tagpovrayorg> wrote:
> A smaller section of the parabola now.
>
>   This beautifully demonstrates *why* parabolic antennas have to be
> perfectly aligned to work properly.

....And why the mirrors in my Newtonian telescope must be perfectly aligned
to get a planet with crisp rings, rather than a yellow oval fuzzball.

What code did you use for the media?  I've tried something similar in the
past without much success.


Post a reply to this message

From: Dave Matthews
Subject: Re: Parabolic mirror 2
Date: 17 May 2005 17:20:00
Message: <web.428a2726408416d18c7259570@news.povray.org>
Warp <war### [at] tagpovrayorg> wrote:
> A smaller section of the parabola now.
>
>   This beautifully demonstrates *why* parabolic antennas have to be
> perfectly aligned to work properly.


Excellently done!  Could you post the source, please?  Or at least the
settings?  I've tried similar things, with very poor results.

Dave Matthews


Post a reply to this message

From: Warp
Subject: Re: Parabolic mirror 2
Date: 17 May 2005 20:34:12
Message: <428a5544@news.povray.org>
Dave Matthews <dma### [at] wrmnwestmnscuedu> wrote:
> Excellently done!  Could you post the source, please?  Or at least the
> settings?  I've tried similar things, with very poor results.

camera { location -z*29 look_at 0 angle 20 }
plane { z, -30 pigment { rgb .6 } finish { ambient 1 } }
light_source
{ -z*29+y*10-x*10, 1 media_interaction off
  photons { reflection off refraction off  }
}

global_settings
{ photons
  { count 1000000
    media 200
  }
}

union
{ intersection
  { quadric { <0, -1, 0>, <0, 0, 0>, <-1, 0, 0>, 0 }
    box { <-.4*.4, .4, -.1>, <.5, -.4, .1> }
    bounded_by { box { <-.4*.4, .4, -.1>, <.5, -.4, .1> } }
    pigment { rgb 0 }
    photons { target reflection on collect off }
    finish { reflection 1 ambient 0 diffuse 0 }
  }
  intersection
  { quadric { <0, -1, 0>, <0, 0, 0>, <-1, 0, 0>, 0 }
    box { <-.4*.4, .4, -.2>, <.5, -.4, .2> }
    bounded_by { box { <-.4*.4, .4, -.2>, <.5, -.4, .2> } }
    pigment { rgb <1,.9,.8> }
    photons { target collect off }
    translate x*.001
  }
  scale 9
  translate x*4.5
}

box
{ <-9, -4, -.11>, <5, 4, .11> hollow
  pigment { rgbt 1 }
  photons { pass_through }
  interior { media { scattering { 1, 1 extinction .001 } } } 
}

#include "transforms.inc"

#macro Light(YOffset, PointAtYOffset, Color)
  light_source
  { <-4, YOffset, 0>, Color*5
    cylinder radius .05 falloff .1 point_at y*(YOffset+PointAtYOffset)
    parallel point_at y*(YOffset+PointAtYOffset)
  }
  cylinder
  { -x*.01, -x, .2
    pigment { rgb Color }
    finish { specular .5 }
    #if(PointAtYOffset != 0)
      Reorient_Trans(-x, -x*4-y*PointAtYOffset)
    #end
    translate <-4, YOffset, 0>
  }
#end

#declare YInd = 3.375;
#declare ColorInd = 0;
#while(YInd >= -3.4)
  Light(YInd, 0, <ColorInd, .8, 1-ColorInd>)
  #declare YInd = YInd-.75;
  #declare ColorInd = ColorInd+1/9;
#end


Post a reply to this message

From: Catseye
Subject: Re: Parabolic mirror 2
Date: 20 May 2005 11:06:30
Message: <428dc4b6$1@news.povray.org>
Ricky,

Ever try to build a POV virtual Newtonian telescope and image a distant 
object through an eyepiece?  I've had good success with the scope and 
(Primary & Secondary) mirrors but haven't tried to build an eyepiece "lens" 
system yet.

"Cousin Ricky" <ric### [at] yahoocom> wrote in message 
news:web.42893a00408416d1755fa2580@news.povray.org...
> Warp <war### [at] tagpovrayorg> wrote:
>> A smaller section of the parabola now.
>>
>>   This beautifully demonstrates *why* parabolic antennas have to be
>> perfectly aligned to work properly.
>
> ....And why the mirrors in my Newtonian telescope must be perfectly 
> aligned
> to get a planet with crisp rings, rather than a yellow oval fuzzball.
>
> What code did you use for the media?  I've tried something similar in the
> past without much success.
>


Post a reply to this message

From: Catseye
Subject: Re: Parabolic mirror 2
Date: 20 May 2005 11:08:52
Message: <428dc544$1@news.povray.org>
Warp,

Thanks a bunch for posting the source code for this.  It's really elegant.

How long does it take to render this on your machine?

"Warp" <war### [at] tagpovrayorg> wrote in message 
news:428a5544@news.povray.org...
> Dave Matthews <dma### [at] wrmnwestmnscuedu> wrote:
>> Excellently done!  Could you post the source, please?  Or at least the
>> settings?  I've tried similar things, with very poor results.
>
> camera { location -z*29 look_at 0 angle 20 }
> plane { z, -30 pigment { rgb .6 } finish { ambient 1 } }
> light_source
> { -z*29+y*10-x*10, 1 media_interaction off
>  photons { reflection off refraction off  }
> }
>
> global_settings
> { photons
>  { count 1000000
>    media 200
>  }
> }
>
> union
> { intersection
>  { quadric { <0, -1, 0>, <0, 0, 0>, <-1, 0, 0>, 0 }
>    box { <-.4*.4, .4, -.1>, <.5, -.4, .1> }
>    bounded_by { box { <-.4*.4, .4, -.1>, <.5, -.4, .1> } }
>    pigment { rgb 0 }
>    photons { target reflection on collect off }
>    finish { reflection 1 ambient 0 diffuse 0 }
>  }
>  intersection
>  { quadric { <0, -1, 0>, <0, 0, 0>, <-1, 0, 0>, 0 }
>    box { <-.4*.4, .4, -.2>, <.5, -.4, .2> }
>    bounded_by { box { <-.4*.4, .4, -.2>, <.5, -.4, .2> } }
>    pigment { rgb <1,.9,.8> }
>    photons { target collect off }
>    translate x*.001
>  }
>  scale 9
>  translate x*4.5
> }
>
> box
> { <-9, -4, -.11>, <5, 4, .11> hollow
>  pigment { rgbt 1 }
>  photons { pass_through }
>  interior { media { scattering { 1, 1 extinction .001 } } }
> }
>
> #include "transforms.inc"
>
> #macro Light(YOffset, PointAtYOffset, Color)
>  light_source
>  { <-4, YOffset, 0>, Color*5
>    cylinder radius .05 falloff .1 point_at y*(YOffset+PointAtYOffset)
>    parallel point_at y*(YOffset+PointAtYOffset)
>  }
>  cylinder
>  { -x*.01, -x, .2
>    pigment { rgb Color }
>    finish { specular .5 }
>    #if(PointAtYOffset != 0)
>      Reorient_Trans(-x, -x*4-y*PointAtYOffset)
>    #end
>    translate <-4, YOffset, 0>
>  }
> #end
>
> #declare YInd = 3.375;
> #declare ColorInd = 0;
> #while(YInd >= -3.4)
>  Light(YInd, 0, <ColorInd, .8, 1-ColorInd>)
>  #declare YInd = YInd-.75;
>  #declare ColorInd = ColorInd+1/9;
> #end


Post a reply to this message

From: Cousin Ricky
Subject: Re: Parabolic mirror 2
Date: 25 May 2005 17:05:01
Message: <web.4294af1e408416d1755fa2580@news.povray.org>
"Catseye" <jpf### [at] comcastnet> wrote:
> Ricky,
>
> Ever try to build a POV virtual Newtonian telescope and image a distant
> object through an eyepiece?  I've had good success with the scope and
> (Primary & Secondary) mirrors but haven't tried to build an eyepiece "lens"
> system yet.

I've done the parabolic primary with good results.  It was just a quick
proof-of-concept thing, so i didn't bother with the secondary or eyepiece.
Parabolic reflection is straightforward, but designing a multiple lens
system requires, um, library books and math.  The secondary would also have
been straightforward, but i didn't see the point without an eyepiece.

Warp's project interested me, because i had once tried to trace the path of
a ray of light through a brilliant round cut diamond.


Post a reply to this message

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.