Hi guys,

I am currently working on a scene with a sphere floating in some water. It
is in it's infant stages, and is more a learning experience than an attempt
at a decent image.

I have the water looking decent nowm, thanks to Chris' page. But I can't get
photons to work. Can I grab some help?

Here is my code:

#include "functions.inc"
#include "Radiosity.inc"
#include "colors.inc"
#include "textures.inc"

global_settings
{
  max_trace_level 5
  /*radiosity
  {
    Radiosity_Settings(1,true,true)  \\This is a macro I made.
  }*/
  photons
  {
      spacing 0.01
      save_file "photons.dat"
  }
}

camera
{
    location <0,10,0>
    look_at <0, 10, 100>
}

sky_sphere
{
    pigment
    {
      color rgb <0.75,0.98,1>
    }
}

light_source
{
 <  0,  3000,    -3000>
 color White
 photons
  {
      reflection on
      refraction off
  }
}

light_source
{
  <0,3000,3000>
  White
  shadowless
}

#declare watermaterial = material
{
  texture
  {
     pigment
     {
        color rgbf <1, 1, 1, 1>
      }
      finish
      {
        ambient 0.0
        diffuse 0.0
        reflection
        {
          0.3,1.0
          fresnel on
        }
        specular 0.4
        roughness 0.003
      }
      /*normal
      {
        bozo 0.3
        scale 5
      }*/
      normal
      {
        function
        {
          f_ridged_mf(x, y, z, 0.1, 3.0, 7, 0.7, 0.7, 2)
        } 0.8
        scale 3
      }
   }
   interior
   {
     ior 1.3
     media
     {
      scattering { 2 <0.5, 0.65, 0.4> }
     }
   }
}

#declare waterbase = plane
{
  y,-1
  pigment { color Black }
}

#declare watertop = plane
{
  y, 0
  material {watermaterial}
}

#declare water = union
{
  object {waterbase}
  object {watertop}
}

#declare Ball = sphere
{
  <0,0,50>,5
  pigment { color Red }
}

#declare Box = box
{
  <-10,-0.001,-10>,<10,0.001,10>
}

object
{
  water
}
object
{
  Box
  photons
  {
    target 0.5
    reflection on
    refraction off
  }
}
object
{
  Ball
  photons
  {
    reflection on
    refraction off
  }
}

Post a reply to this message

> I am currently working on a scene with a sphere floating in some water. It
> is in it's infant stages, and is more a learning experience than an
attempt
> at a decent image.
>
> I have the water looking decent nowm, thanks to Chris' page. But I can't
get
> photons to work. Can I grab some help?

First: povray.animations might be the wrong group for this kinda post, cause
there's nothing that has to do with animations in your problem...

Second: your box and your ball don't have proper textures for the photons to
interact with. POV shoots the photons but they will only appear if the
box/ball actually reflect or refract the photons. The Box doesn't have a
texture at all, whereas the ball is just plain red, both don't have any
finish with reflection. Hence, no photons get reflected off of them.

Now, if you want photons to appear on the ball and box, e.g. reflections off
the water, then the water would have to be the target.

I've haven't rendered the scene and I didn't look too much where objects are
placed in relation to each other, but without a proper texture, ball and box
won't work with photons. That's all covered with the Docs, so maybe you
should go back to those and read them once again.

Regards,
Tim

-- 
"Tim Nikias v2.0"
Homepage: <http://www.nolights.de>
Email: tim.nikias (@) nolights.de

Post a reply to this message

"Tim Nikias v2.0" wrote:

> First: povray.animations might be the wrong group for this kinda post, cause
> there's nothing that has to do with animations in your problem...

povray.newusers would be the appropriate group for this type of question.

-- 
Ken Tyler

Post a reply to this message

"Ken" <ken### [at] tagpovrayorg> wrote in message
news:403EA7B4.5F001F27@tag.povray.org...
>
> "Tim Nikias v2.0" wrote:
>
> > First: povray.animations might be the wrong group for this kinda post,
cause
> > there's nothing that has to do with animations in your problem...
>
> povray.newusers would be the appropriate group for this type of question.

Maybe it was going to animated later.  ;-)

Not only is the Box object not reflective (or anything else), it just
doesn't make sense what it's doing there. Maybe was to be a container for
the media? Those two planes are obvious anyhow, for top and bottom surfaces
while having separate textures. If photons are to hit the bottom plane
though, it really shouldn't be black. Maybe media scattering was only thing
in mind and not for there to be dappled light reaching the bottom. Sorry if
I am speculating too much.

So... there *is* a water material and the object its applied to. It ought to
be the thing with a photons statement most of all.

Doing the following might be correct if the box is intended as basin for
water:

#declare waterbase = plane
{
  -y,-1
  pigment { color rgb 0 }
}

#declare watertop = plane
{
  y, 0
  material {watermaterial}
}

#declare water = union
{
  object {waterbase}
  object {watertop}
}

#declare Box = intersection {
box
{
  <-100,-1.001,25>,<100,0.001,100>
}
object
{
  water
}
}

object
{
  Box
  photons
  {
    target 0.5
    reflection on
    refraction off
  }
 hollow // for media to show
}

That red Ball doesn't need photons block unless to specify 'collect off' for
it or it gets a reflection added to the texture, like Tim was saying. My
changes here make the whole scene different so it's still not clear to me
what was intended by it (the Box mainly).

-- 
Bob H.
http://www.3digitaleyes.com

Post a reply to this message