On Fri, 23 Jan 2009 18:40:53 +0100, clipka <nomail@nomail> wrote:
> Are you sure you attached a POV scene file? IE just presents me with the  
> same text you wrote in your post...

He did. Contents below. I tested the scene with  
3.7.0.beta.30.msvc8-sse2.win32 and could reproduce the problem by changing  
the number on line 77 to 5.



/////////////////////////////////////////////////////////////////////////////
// Include Files

#include "colors.inc"
#include "metals.inc"

/////////////////////////////////////////////////////////////////////////////
// Declared pigments, finishes, etc.

#declare sky_vect = z;
#declare lookat = <0, 0, 0>;
#declare cam_loc = lookat+(<.5, 1, .25>*600);
#declare cam_zoom = 10;
#declare light_loc = <1, .5, .25>*500000;

global_settings
{
	max_trace_level 12
	assumed_gamma 2.2
}

background { Black }
#default
{
	pigment { rgb<.70, .70, .75> }
	finish
	{
     ambient .25
	  diffuse .75
	  reflection 0
	  phong 0
	  phong_size 30
	  brilliance .5
	}
}

/////////////////////////////////////////////////////////////////////////////
// Lights

light_source
{
   light_loc
   colour rgb<1, 1, 1>
}

/////////////////////////////////////////////////////////////////////////////
// Camera

camera
{
   location cam_loc
   direction <cam_zoom,0,0>
   up sky_vect
   right <0, -(image_width/image_height), 0>
   sky sky_vect
   look_at lookat
}

/////////////////////////////////////////////////////////////////////////////
// Objects

#local r=8.5852/2; //.338in

#local CaselessBullet=
intersection
{
	cylinder{<0, 0, 0>, <39.5, 0, 0>, r translate<-12.5, 0, 0>}
	#local rx=0;
	#while(rx<360)
		sphere
		{
			0, 1
			scale<67, 15, 50>
			translate<0, 0, -50+r>
			rotate<rx, 0, 0>
		}
		#local rx=rx+5.715;
	#end
	translate<12.5, 0, 0>	
}

difference
{
	object{CaselessBullet	texture{T_Chrome_5C}}
	plane{-y, 0}
	cutaway_textures
}





-- 
FE

Post a reply to this message