|
|
In article <378ea698@news.povray.org>, "John Bauman"
<bau### [at] ptdprolognet> wrote:
>Jerry wrote in message ...
>>In article <378cf848@news.povray.org>, "John Bauman"
>><bau### [at] ptdprolognet> wrote:
>>
>>>I'm making plasma exhaust for the ship that I'm building.
>>>I'm very unhappy with the fact that it is only a little blue only on the
>>>edges.
>>>There isn't any density type called conical, so what should I do?
>>
>>You might be able to fake a conical density type by multiplying a
>>cylindrical density type with gradient y?
>I did a gradient y, but I dont know how to multiply a cylindrical density by
>it
Basically you just stick multiple densities after each other and they multiply:
#declare Final_Render = 1;
//units in feet
//east is negative x
//north is positive z
#include "colors.inc"
#include "skies.inc"
#include "woods.inc"
#if (Final_Render > 0)
#declare minsamples = 2;
#declare maxsamples = 12;
#declare fogvariance = 40/1000;
#declare fogconfidence = 0.98;
#declare fogintervals=1;
#else
#declare minsamples = 1;
#declare maxsamples = 4;
#declare fogvariance = 100/1000;
#declare fogconfidence = 0.7;
#declare fogintervals=1;
#end
cylinder {
<0,0,0>,<0,1,0>,1.0001
pigment {
color rgbf <1,1,1,1>
}
interior {
media {
scattering { 1, 1}
intervals fogintervals
samples minsamples, maxsamples
confidence fogconfidence
variance fogvariance
density {
gradient y
color_map {
[0 color rgb <1, 1, 1>]
[1 color rgb <0, 0, 0>]
}
}
density {
cylindrical
color_map {
[0.0 color rgb <0,0,0>]
[1.0 color rgb <1,1,1>]
}
}
}
}
hollow
scale 2
}
camera {
location <0,.3,-4>
look_at <0,.5,0>
}
light_source {
<-100,500,-75>,
color White
}
sky_sphere {
pigment {
gradient y
pigment_map {
[0.01 rgb <0.847, 0.749, 0.747> ] // horizon
[0.25 P_Cloud2 scale 0.25 rotate z*5]
[0.60 P_Cloud3 scale <0.25, 0.15, 0.25> rotate z*10]
}
}
}
Post a reply to this message
|
|