On Wed, 14 Nov 2001 10:03:04 -0500, "Cris Williams" <wor### [at] netscapenet>
wrote:

> I'm looking for a Mesh2 file that uses all of the Mesh2 features.  I am
> playing around with writing a program to manipulate meshes and I'd like to
> thoroughly check my parser code.  Does anyone have a Mesh2 file like this on
> a web site that I can download?  Thanks.

Check this:

#version 3.5;

camera {
  location  <0.0, 0.5, -4.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   0
}

light_source { <-30, 30, -30> color rgb 1 }

#local Texture1=texture{pigment{color green 1}}

mesh2{
  vertex_vectors{
    8
    (x+z+y) (x-z+y) (-x-z+y) (-x+z+y)
    (x+z-y) (x-z-y) (-x-z-y) (-x+z-y)
  }
  normal_vectors{
    3
    x y z
  }
  uv_vectors{
    4
    <0,0><0,1><1,1><1,0>
  }
  texture_list{
    3,
    texture { Texture1 },
    texture { pigment{color red 1} }
    texture { pigment{color blue 1} }
  }
  face_indices{
    4,
    <4,5,6>,0,
    <4,6,7>,0,1,2,
    <0,1,2>,
    <0,2,3>,
  }
  normal_indices{
    1
    <0,1,2>
  }
  uv_indices{
    4,
    <0,1,2>
    <0,2,3>
    <0,1,2>
    <0,2,3>
  }
  texture{pigment{color rgb 1}}
  rotate y*30
  rotate -x*10
  scale .5
}

ABX
--
#declare _=function(a,b,x){((a^2)+(b^2))^.5-x}#default {pigment{color rgb 1}}
union{plane{y,-3}plane{-x,-3}finish{reflection 1 ambient 0}}isosurface{ //ABX
function{_(x-2,y,1)|_((x+y)*.7,z,.1)|_((x+y+2)*.7,z,.1)|_(x/2+y*.8+1.5,z,.1)}
contained_by{box{<0,-3,-.1>,<3,0,.1>}}translate z*15finish{ambient 1}}//POV35

Post a reply to this message