Wasn't it Chuck Roberts who wrote:

>I have tried spherical, spotted/bozo, and leopard. They all have
>turbulence in them, which I don't want. I want a pattern of
>perfect circles. I guess the texture is not the way to go.
>Perhaps I'll have to make an image for an image map. But thanks.

You might consider trying to design your own (iso)pigment.

Something like this might be a starting point:-

box {-5,5
  pigment { function {sin(x)^2*sin(y)^2*sin(z)^2}
    color_map { [0.20 rgb <1,0,1>]
                [0.20 rgb <1,1,0>]
    }
  }
}

Rendering the isosurface that is associated with this isopigment miught
help you visualize what's going on:-

isosurface {function {sin(x)^2*sin(y)^2*sin(z)^2}
  threshold 0.2
  sign -1
  contained_by {box -5,5}
  pigment {rgb <1,1,0>}
}

The difference between this isopigment and the leopard pigment is that
the blobs are packed differently. The different packing patterns might
look better or worse, depending on the shape of the object you are
painting. You can visualize the 3d leopard pigment like this:-

#declare F=function{pigment{
  leopard 
  turbulence 0.0
  color_map { [0 rgb 1] [1 rgb 0] }
  scale 0.6
  }
}
isosurface {
   function { F(x,y,z) }
   threshold 0.5
   contained_by{box{-5,5}}
   pigment {rgb <1,1,0>}
}

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message