Wasn't it busabus who wrote:
>I've been out of the POV scene for quite a few years (since I left
>compuserve!) and I'm trying to get back into it.
>
>I'm attempting to create a 3D 5-pointed star that is faceted like a gem,
>kind of like this
>http://www.lidinc.com/Merchant2/graphics/00000001/SM%20STAR%20K166%20GIF.jpg,
>and it's bugging me.  I know I could create it by calculating the points
>and putting them into a mesh, but there must be a simpler way of getting
>POV to do all the hard work.
>
>Any pointers/links etc would be really helpful.

How about using five stretched octahedrons, something like this but with
better material and lighting?

#version 3.6;
global_settings {
  assumed_gamma 1.0
  max_trace_level 15  
}
camera {location  <-4,5,-20> look_at <0,0,0> angle 40}
background {rgb 1}
light_source {<-30, 100, -30> color rgb 1}

#include"shapes.inc"
#include"shapes2.inc"
#include"glass.inc"

union {
  #declare N=0;
  #while (N<5)
    object{Octahedron
      scale <1,1.9,1>       // stretch in y direction
      rotate y*45           // bring an edge to the front
      translate y*1.3       // move away from centre
      rotate z*360/5*N      // rotate each point
    }
    #declare N=N+1;
  #end
  texture {T_Old_Glass}
  interior {I_Glass1}
}



-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message