|
![](/i/fill.gif) |
Wasn't it Oleguer Vilella who wrote:
>Well, I'm sorry, maybe is my English...
>I want to double the torus. I want make an angle in the middle of the torus
>like a bridge. For exemple: if the torus has 4cm I want to make an angle of
Are either of these anything like what you are after? Change the "Bend"
and "Sharpness" parameters as necessary.
//-----------------------------------------------------------------
#include "functions.inc"
camera { location <-0, 1, -4> look_at <0, 0, 0> angle 29}
background {rgb 1}
light_source {<-100,200,-100> colour rgb 1}
#declare Bend=0.6;
#declare Sharpness=1.7;
isosurface {
function { f_torus(x,y+pow(abs(x),Sharpness)*Bend,z,0.8,0.15) }
max_gradient 1.5
contained_by{sphere {0,1.2}}
pigment {rgb .9}
}
//-----------------------------------------------------------------
#include "functions.inc"
camera { location <-0, 1, -4> look_at <0, 0, 0> angle 40}
background {rgb 1}
light_source {<-100,200,-100> colour rgb 1}
#declare Bend=0.4;
#declare Sharpness=1.7;
isosurface {
function { f_torus(y+pow(abs(x),Sharpness)*Bend,z,x,0.8,0.15) }
max_gradient 1.5
contained_by{sphere {0,1.2}}
pigment {rgb .9}
}
//------------------------------------------------------------------
Although it's nothing to do with your question, here's the same thing
with some different values of Bend and Sharpness and a slightly larger
contained_by sphere.
#include "functions.inc"
camera { location <-0, 1, -4> look_at <0, 0.1, 0> angle 40}
background {rgb 1}
light_source {<-100,200,-100> colour rgb 1}
#declare Bend=-0.5;
#declare Sharpness=0.8;
isosurface {
function { f_torus(y+pow(abs(x),Sharpness)*Bend,z,x,0.8,0.15) }
max_gradient 1.5
contained_by{sphere {0,1.5}}
pigment {rgb x}
}
Post a reply to this message
|
![](/i/fill.gif) |