"Tom Melly" <tom### [at] tomandlucouk> wrote in news:3e5b7cca@news.povray.org

>>
>> Yep, that's it - adding to media container
>>   photons { target }
>> do help.
> Are you sure? It doesn't/didn't help on my tests here.

uhm... yes, working scene source is :



#local QQ_Media=1;
camera {
  location <0,8,-9> look_at -y*6 angle 70
}
box { -10,+10 inverse hollow pigment { checker rgb .85 rgb 1 } finish { diffuse .97 }
}
plane { y,-9.99 pigment { rgb 1 } finish { diffuse .96 } }

global_settings {
 radiosity { media on }
 max_trace_level 10
 photons { 
   spacing 0.05
   media 20,2
   max_trace_level 5
 }
}

// ==  glass +normal + PHOTONS
#local Tr=+x*0;
#local P=<0,  2,0>+Tr;
#local T=<0,-10,0>+Tr;
sphere { P .1 finish { ambient 1 } pigment{rgb 1} no_shadow hollow photons {
pass_through } }
sphere { T .2                      pigment{rgb y}  }
light_source { 
  P rgb 1
  spotlight point_at T  radius 10 falloff 10+5
  media_interaction
  media_attenuation
  photons { reflection on  refraction on }
} 
box { -.7,+.7 scale <1,.2,1>
  pigment { rgbf .99 }
  finish { reflection .2 specular .9 roughness 0.02 }
  interior { ior 1.3 }
  normal { bozo scale .4 }
  translate <0,-1,0> translate Tr
  photons { refraction on  reflection off target on }
}
// --- media ---
#if (QQ_Media)
  box {
    <-11,-11,-11> <+11,+11,+11>
    pigment { rgbt 1 }
    interior {
      media {
        method 3 
        samples 5  intervals 2                
        scattering { 1 rgb .10 extinction 0.40 }
      }
    }  
    photons{ target on  } // <======
    hollow
  }  
#end






-- 
#macro g(U,V)(.4*abs(sin(9*sqrt(pow(x-U,2)+pow(y-V,2))))*pow(1-min(1,(sqrt(
pow(x-U,2)+pow(y-V,2))*.3)),2)+.9)#end#macro p(c)#if(c>1)#local l=mod(c,100
);g(2*div(l,10)-8,2*mod(l,10)-8)*p(div(c,100))#else 1#end#end light_source{
y 2}sphere{z*20 9pigment{function{p(26252423)*p(36455644)*p(66656463)}}}//M

Post a reply to this message