David Mathog wrote:

>......
>Then I try to put labels into the frame so that they are stable in the 
>viewed frame.

If it helps, here's a bit by John VanSickle, couldn't find the original so 
copied it from a scene.


////// this part by John van Sickle
#local CamL= <0,1.6,-5>; //where the camera's location is
#local CamE= <0,0,0>;   //where the camera's look_at is
#local CamZ= 2;         //the amount of camera zoom you want

#local CamD= vnormalize(CamE-CamL);
#local CamR= vnormalize(vcross(y,CamD));
#local CamU= vnormalize(vcross(CamD,CamR));

text { ttf "arial.ttf","Your Text",0.01,0
   texture { pigment {rgb 12} }
   scale .1
   translate < 0.3,-0.45, CamZ>
   matrix < CamR.x, CamR.y, CamR.z,
            CamU.x, CamU.y, CamU.z,
            CamD.x, CamD.y, CamD.z,
            CamL.x, CamL.y, CamL.z >
}

camera {
   location CamL
   up CamU
   right CamR*4/3
   direction CamD*CamZ
}        
///////


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message