|
|
Wasn't it Jared who wrote:
>Hey all,
>I'll get right to it:
>
>- In my final output, I would like objects passing through an area defined
>by a word (I'll use "text" as an example) to have a certain texture. I
>don't know how to define a texture area as the area inside a text, so if
>anyone knows anything about this, help would be GREATLY appreciated.
>- There will be many objects moving in the frame (some of which aren't
>directly defined) leading me to believe it would be impracticle to "hide"
>and replace objects as they enter the area created by the text (my original
>plan).
Look up "object pattern" and, if necessary, "text object" in the
documentation. You get something like this:-
global_settings {assumed_gamma 1.0}
camera {location <1,1,-3> look_at <1,0,0>}
light_source {<0,3,-5> color rgb 1}
#declare T= text {ttf "ariblk.ttf", "TEXT", 20, 0}
#declare TXTURE = texture {
object {T
texture {pigment {rgb 1}},
texture {pigment {wood scale 0.1 turbulence 0.2} normal{granite}}
}
}
sphere {<0,0,1>,1 texture {TXTURE}}
sphere {<1,1,1>,0.6 texture {TXTURE}}
sphere {<2,0.2,1>,0.4 texture {TXTURE}}
sphere {<2.6,0.4,1>,0.3 texture {TXTURE}}
// Adding the following line helps you position the text
// which might be quite difficult if it happens to miss everything
//object {T pigment {rgb 0.5}}
Post a reply to this message
|
|