On Mon, 29 Jul 2002 09:58:43 -0500, Richard Morehouse
<rmo### [at] coxnet> wrote:

>I am still a bit of a noobie at this so i will have a lot of
>questions. 

That's what these newsgroups are for, after all.

>how would I change the glass objects?

Removing the transparency should suffice. If you have reflection,
remove that as well.

>how does colored glass affect this?

Most people use a high ambient and low diffuse for glasses. When you
remove the transparency, the colored glass will color its surroundings
- maybe not very realistically, maybe vice versa, you'll have to try
and see if you like it :)

>what about metal objects? I use quite a lot of the Polished_Chrome
>texture

Well, use the same texture but without reflection. Read on.

>and water?

Same as glass.

>do i need to change any other finish statements? ie: finish {shiny}

Anything that has reflection and/or transparency - I think Shiny in
particular does not, but you should check.

>could i use an ini file to do both renders one after the other?

Of course :)

Here is a rough draft of what you should do - I am writing this
directly in the newsreader so I can't test it at the moment but it
should give you an idea. Render as an animation with two frames - that
is, command line switches +kfi0 +kff1 

// The first frame is the pretrace, the second is the trace
#if (clock<0.5)
  #declare Pretrace = true;
#else
  #declare Pretrace = false;
#end

global_settings {          
  radiosity {              
    count 100
    nearest_count 5        
    error_bound 1.8        
    recursion_limit 3      
    low_error_factor .5    
    gray_threshold 0.0     
    minimum_reuse 0.015    
    brightness 1           
    adc_bailout 0.01/2     

// Now, if we are pretracing, use high quality settings and save a
// nice, dense radiosity file

#if (Pretrace)
    pretrace_start 0.08
    pretrace_end   0.01
    always_sample on
    save_file "provide_file_name_here"

// Otherwise, load the file and do not calculate additional samples

#else
    pretrace_start 1
    pretrace_end   1
    always_sample off
    load_file "provide_file_name_here"
#end

  }                        
}

// Here is an example of how to make a glass material
// Shows how to switch reflection and transparency on/off

#declare MyGlassMaterial = material {
  texture {
    pigment {
      color rgb <0.95,0.975,1>

// Only add transparency if not pretracing

#if (!Pretrace)
      filter 0.95
#end
    }
    finish {
      ambient 0.8 diffuse 0.2 brilliance 0.8
      specular 0.4 roughness 0.0005
      phong 0.2 phong_size 7.5

// Only add reflection if not pretracing

#if (!Pretrace)
      reflection 0.075
#end
    }
  }

  interior { ior 1.765 }
}

>after my first post i started the render again without area lights.
>this is making a big difference in render time. 

>is the difference in quality significant enough with area lights to
>make it worthwhile. ?

Try without radiosity first and see whether area lights are
contributing enough to your scene to pay the price.

I hope you get a more clearer idea of what I tried to explain in my
last post. My code probably may not run the first time but it should
at least tip you in the right direction.


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] vipbg
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message