On 24-2-2018 17:07, Mike Horvath wrote:
> On 2/23/2018 8:18 AM, Alain wrote:
>> The 3 lumen looks a little to bright.
>> Can you post the 1 lumen image?
>>
>> Also, the sun position is not the same for the two images. It mover by 
>> around 40°.
> 
> Here it is with RGB instead of SRGB, and 1 lumens.
> 
> https://i.imgur.com/AcGBbla.jpg
> 
> As you can see, it is pretty dim and lifeless.
> 

On my screen it looks right.

I often use CIE.inc myself, maybe in a little different way than you do. 
This is an example of how I define my sunlight in a scene:

//start code -----------------------------------
#include "CIE.inc"
#if (Fog)
   #local Intensity    = 5;
#else
   #local Intensity    = 3;
#end
//Sun's temperature (Kelvin): 2800=red; 7500=blue white
#declare SunColor     = Blackbody(6500)*Intensity;
#declare SunPosition  = <0, 0, -2>*10e4;
#declare SunDis       = vlength(SunPosition)*2/215;
#declare Sun_alt      = 60;
#declare Sun_azm      = -115;

#if (Area)
   #debug "\nUsing an area_light for the Sun.\n"
   light_source{
     <0, 0, 0>
     color SunColor
     area_light
     SunDis*x, SunDis*z, // lights spread out (x * z)
     4, 4                // total lights in grid (4x*4z = 16 lights)
     adaptive 1          // 0,1,2,3...
     area_illumination on  // full area diffuse and specular
     jitter              // adds random softening of light
     circular            // make the shape of the light circular
     orient              // orient light
     translate SunPosition
     rotate Sun_alt*x
     rotate Sun_azm*y
     parallel
     point_at <0, 0, 0>
     media_interaction on
     media_attenuation off
   }
#else
   light_source {
     <0, 0, 0>
     color rgb SunColor
     translate SunPosition
     rotate Sun_alt*x
     rotate Sun_azm*y
     parallel
     point_at <0, 0, 0>
     media_interaction on
     media_attenuation off
   }
#end
//end code -----------------------------------


-- 
Thomas

Post a reply to this message