|
 |
CODE
--------------------------
#version 3.8;
#declare MyRadiosity = on;
global_settings
{
assumed_gamma 1.4
#if(MyRadiosity=on)
radiosity { media on }
#end
}
#default
{
finish { ambient 0.0 diffuse 1.0 }
}
//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
//------------------------------------------------------------------------
camera
{
/*ultra_wide_angle*/ //angle 20
location < -35.0 , 11.0 , 0.0 >
//right x*image_width/image_height // not needed for v3.8
look_at < 0.0 , 5.0 , 0.0 >
}
// sun -------------------------------------------------------------------
light_source
{
-z*9999.0//< 50, 100, -250 >*10e4
color 1.0 * 1.4//< 1.0, 0.62353, 0.46667 >*2
rotate < 20.0, 240.0, 0.0 > // altitude, azimuth, tilt
}
// sky -------------------------------------------------------------------
background { color rgb 0.0 }
disc
{
0.0, y, 1.0, 0.0
hollow on
no_shadow
pigment { rgb < 0.5, 0.75, 1.0 > }
scale 100.0
translate y*100.0
}
// ground -----------------------------------------------------------------
box
{
< -1.0, -1.0, -1.0 > < 1.0, 1.0, 1.0 >
pigment { color rgb 1.0 }
scale < 555.0, 497.0, 555.0 >
translate -y*494.0
}
//-------------------------------------------------------------------------
-
// Clouds
#local Scale = 5.0;
#declare Clouds = density
{
ripples // controls the cloud formation
color_map
{
[ 0.33 rgb 10.0 ]
[ 0.67 rgb 100.0 ]
}
scale < 3.0, 1.0, 10.0 >*0.5
warp { turbulence < 2.5, 1.0, 1.6 > }
rotate 45.0*y
}
//cloud layer:
box
{
< -1.0, -1.0, -1.0 > < 1.0, 1.0, 1.0 >
pigment { rgbt 1.0 }
hollow
interior
{
media
{
samples 20
absorption < 3.0, 4.0, 0.5 >*1.0/(Scale*100.0)
emission < 1.0, 1.0, 1.0 >*0.5/(Scale*100.0)
scattering
{
1
< 0.5, 0.75, 1.5 >*3.0/(Scale*100.0)
extinction 0.5
}
density
{
boxed
density_map
{
[ 0.000 rgb 0.0 ]
[ 0.001 Clouds scale 1.0/100.0 ]
}
}
}
}
scale Scale*100.0
translate -y*494.0
}
//-------------------------------------------------------------
//atmosphere:
sphere
{
< 0.0, 0.0, 0.0 >, 1.0
pigment { rgbt 1.0 }
hollow
interior
{
media
{
samples 20
absorption 0.5
scattering
{
5
< 1.25, 1.0, 1.5 >*2.0/Scale
extinction 0.67
eccentricity 0.2
}
density
{
gradient y
color_map
{
/*
[ 0.00 rgb 1.0 ] //base ground fog
[ 0.10 rgb < 9.0, 0.3, 0.10 > ] //top ground fog
[ 0.30 rgb < 0.9, 0.3, 0.10 > ] //top ground fog
[ 0.50 rgb < 0.5, 0.1, 0.09 >*0.100 ] //base atmospheric haze
[ 0.67 rgb < 0.1, 0.2, 0.90 >*0.100 ] //top atmospheric haze
[ 1.00 rgb < 0.1, 0.3, 0.90 >*0.001 ] //top atmospheric haze
*/
[ 0.00 rgb < 1.0, 1.0, 1.00 >*1.000 ] //base ground fog
[ 0.10 rgb < 3.0, 0.3, 0.10 >*1.000 ] //top ground fog
[ 0.30 rgb < 0.3, 0.3, 0.10 >*1.000 ] //top ground fog
[ 0.50 rgb < 0.5, 0.1, 0.09 >*0.100 ] //base atmospheric haze
[ 0.67 rgb < 0.3, 0.7, 1.00 >*0.100 ] //top atmospheric haze
[ 1.00 rgb < 0.3, 0.7, 1.00 >*0.001 ] //top atmospheric haze
}
rotate -x*15.0
warp { spherical }
scale Scale*2.0*y
}
}
}
scale Scale*111.0
translate -y*535.0
}
//-------------------------------------------------------------
// Planet:
union
{
sphere
{
< 0.0, 0.0, 0.0 > 7.0
pigment
{
gradient y
color_map
{
[ 0.00 rgb < 1.0, 1.0, 1.0 >*0.25 ]
[ 0.10 rgb < 1.0, 1.0, 1.0 >*0.25 ]
[ 0.12 rgb < 1.0, 1.0, 1.0 >*0.25 ]
[ 0.15 rgb < 0.80392, 0.66275, 0.47059 >*0.25 ]
[ 0.20 rgb < 0.80392, 0.66275, 0.47059 >*0.25 ]
[ 0.22 rgb < 0.63922, 0.55686, 0.31373 >*0.25 ]
[ 0.27 rgb < 0.63922, 0.55686, 0.31373 >*0.25 ]
[ 0.40 rgb < 0.47451, 0.30980, 0.14118 >*0.25 ]
[ 0.43 rgb < 0.47451, 0.30980, 0.14118 >*0.25 ]
[ 0.45 rgb < 0.20392, 0.24314, 0.41176 >*0.25 ]
[ 0.55 rgb < 0.20392, 0.24314, 0.41176 >*0.25 ]
[ 0.57 rgb < 0.47451, 0.30980, 0.14118 >*0.25 ]
[ 0.60 rgb < 0.47451, 0.30980, 0.14118 >*0.25 ]
[ 0.73 rgb < 0.63922, 0.55686, 0.31373 >*0.25 ]
[ 0.78 rgb < 0.63922, 0.55686, 0.31373 >*0.25 ]
[ 0.80 rgb < 0.80392, 0.66275, 0.47059 >*0.25 ]
[ 0.85 rgb < 0.80392, 0.66275, 0.47059 >*0.25 ]
[ 0.88 rgb < 1.0, 1.0, 1.0 >*0.25 ]
[ 0.90 rgb < 1.0, 1.0, 1.0 >*0.25 ]
[ 1.00 rgb < 1.0, 1.0, 1.0 >*0.25 ]
}
turbulence 0.3
translate < 0.0, -7.0, 0.0 >
scale 14.0
}
}
difference
{
cylinder { < 0.0, -0.00001, 0.0 > < 0.0, 0.00001, 0.0 > 16.0 }
cylinder { < 0.0, -0.00002, 0.0 > < 0.0, 0.00002, 0.0 > 10.0 }
pigment
{
onion
color_map
{
[ 0.00 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.60 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.62 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.63 rgb < 0.80392, 0.66275, 0.47059 > ]
[ 0.66 rgb < 0.80392, 0.66275, 0.47059 > ]
[ 0.67 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.71 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.73 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.76 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.80 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.81 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.82 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.83 rgb < 0.47451, 0.30980, 0.14118 > ]
[ 0.86 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.88 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.89 rgb < 0.80392, 0.66275, 0.47059 > ]
[ 0.91 rgb < 0.80392, 0.66275, 0.47059 > ]
[ 0.97 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 0.99 rgb < 0.63922, 0.55686, 0.31373 > ]
[ 1.00 rgb < 0.63922, 0.55686, 0.31373 > ]
}
scale 16.0
}
finish { crand 1.0 emission 0.1 }
}
scale 250.0
rotate < -10.0, -20.0, 50.0 >
translate < 160.0, 50.0, -100.0 >*33.0
}
// Big Sun
sphere
{
< 0.0, 0.0, 0.0 > 1.0
pigment
{
gradient y
color_map
{
[ 0.00 rgb < 0.0, 0.0, 0.0 > ]
[ 0.50 rgb < 0.0, 0.0, 0.0 > ]
[ 1.00 rgb < 3.0, 0.0, 0.1 >*5.0 ]
}
translate < 0.0, -0.5, 0.0 >
scale 2.0
}
finish { emission 1.0 }
scale 12.0
scale 33.0
translate < 80.0, -0.0, 35.0 >*33.0
}
// Small Sun
sphere
{
< 0.0, 0.0, 0.0 > 1.0
pigment { color rgb < 0.1, 0.3, 20.0 >*10.0 }
finish { emission 2.0 }
scale 33.0
translate < 80.0, 12.0, 46.0 >*33.0
}
//-------------------------------------------------------------
//artefact:
#local S=seed(4132);
union
{
#for (It,1.0,8.0,1.0)
#local xR=rand(S);
#local yR=rand(S);
#local zR=rand(S);
#local xR2=rand(S);
#local yR2=rand(S);
#local zR2=rand(S);
box
{
0.0, 1.0
scale < 1.0+xR, 8.0+yR*4, 1.0+zR >/2.0
pigment
{
checker
color rgb 0.1 color rgb 0.9 scale 0.5
}
translate (-< xR*20.0,0.0,zR*20.0 > + <xR2*40.0, 0.0, zR2*40.0 >)/2.0
}
#end
rotate y*90.0
translate < -20.0, 2.0, 5.0 >
}
---
http://www.avg.com
Post a reply to this message
|
|
