On 23-7-2016 2:55, Bald Eagle wrote:
> That's a great looking cloud formation you have there.  I very much like the way
> you have the varying colors in different portions of the cloud mass, and the way
> the light strikes them from that "underneath" angle.
>
> I think you've grasped the essentials of the lighting and the colors, and the
> manner that your lighting evokes that - late afternoon illumination of something
> near by something so very big but so very far away.  If this is a new avenue of
> expression, I very much look forward to seeing LOTS more of it   :)
>
> Very nice work, Thomas.
>

Thank you very much indeed. This was the first image I was really 
satisfied with after a long series of test that were interesting at 
best. It is a very delicate matter with a large number delicate 
parameters all influencing each other. For now I am mainly playing with 
density variations which - it must be said - do not create really 
/realistic/ cloud patterns, but the idea is perfectly applicable of 
course on Gilles Tran's MakeCloud objects. However, I am not really 
after true realism in general so I am just searching for that one 
pattern that attracts me.

This particular pattern is based on a bozo density pattern. Samples are 
low in this example but in most cases using other patterns need to be 
increased to possibly 100.

Quick-and-dirty:

//---------------start code
#declare AtmosScale = <10, 10, 10>;

#declare Density_in =
density {
   //spiral1 4
   //marble
   //granite
   bozo
   //spherical
   frequency 6
   color_map {
     [0.30 rgb <0.00, 0.00, 0.00>]
     [0.48 rgb 0.9]
     [0.52 rgb 0.9]
     [0.70 rgb <0.00, 0.00, 0.00>]
   }
   scale 5
   //rotate 90*x	//when using spirals; either here or:
   scale 50
   warp {turbulence <2, 4, 2>*1}
   scale 1/50
   //rotate 90*x	//when using spirals; here
}

#declare Density_out =
density {
   //spherical
   //color_map {
     /*[1.0*/ rgb <0.00, 0.00, 0.00>//]
   //}
}

#declare Atmosphere =
difference {
   sphere {0, 1000}
   sphere {0, 600}
   hollow
   material {
     texture {pigment {color rgbt 1} finish {ambient 0 diffuse 0}}
     interior {
       media {
         // (---general values---)
         intervals 1
         samples 5
         scattering {1, rgb <1,1,1>*0.05/AtmosScale}

         // (---method---)
         //method 3           // adaptive sampling
         //aa_threshold 0.1   // accuracy threshold for method 3 [0.1]
         //aa_level 4         // maximum recursion depth for method 3 [4]
         //jitter 0.5         // randomness for method 2&3

         // (---density---)
         density {
           spherical
           density_map {
             [0.1 Density_out]
             [0.9 Density_in]
           }
           warp {turbulence 0.3}
           scale 900
         }
       }
     }
   }
   scale AtmosScale
   scale <5, 1.0, 5>
   rotate 45*y
}
//---------------end code

-- 
Thomas

Post a reply to this message