I have a tiny mini scene, but it takes forever to render it. Wow.

Please let me know, how long this scene needs on your computer.

800x600, AA 0.3, highest quality, radiosity settings as defined inside
the scene.

------------------------------

#version 3.7;

#declare MyRadiosity             = on; // on or off
#declare MediumRadiosity         = off;
#declare FastRadiosity           = on;

global_settings
{
 #if(MyRadiosity)
  radiosity
  {
   media on
   pretrace_start 0.08
   #if(FastRadiosity)
    pretrace_end   0.015
   #elseif(MediumRadiosity)
    pretrace_end   0.008
   #else
    pretrace_end   0.001
   #end
   count 400
   error_bound 0.75
   recursion_limit 1
  }
 #end
 adc_bailout       0.0039
 ambient_light     rgb < 1.000, 1.000, 1.000 >
 assumed_gamma     1.000
 irid_wavelength   rgb < 0.250, 0.180, 0.140 >
 max_trace_level   5
 number_of_waves   10
 noise_generator   3
 charset           ascii
}

camera
{
 location < -1.0, 1.0, -1.0 >
 look_at  <  0.0, 0.5,  0.0 >
 right 1.77*x
}

background { rgb < 0.50980, 0.52157, 0.99216 > * 0.525 }

light_source
{
 < 10.0, 10.0, -10.0 >
 rgb < 1.0, 1.0, 1.0 > * 0.5
}

light_source
{
 < 10.0, 10.0, -10.25 >
 rgb < 1.0, 1.0, 1.0 > * 0.5
}

light_source
{
 < 10.0, 10.25, -10.0 >
 rgb < 1.0, 1.0, 1.0 > * 0.5
}

light_source
{
 < 10.0, 10.25, -10.25 >
 rgb < 1.0, 1.0, 1.0 > * 0.5
}

#declare MyGlass = texture
{
 pigment { rgbt < 0.00784, 0.99216, 0.60000, 0.8 > }
 finish { reflection 0.5 }
}

// ---------------------------------------------------------------------


// 42 93 26 x 0.6

box // Back
{
 < -0.21, 0.0, 0.254 > < 0.21, 0.93, 0.26 >
 texture { MyGlass }
}

box // Left
{
 < -0.21, 0.0, 0.0 > < -0.204, 0.93, 0.26 >
 texture { MyGlass }

}

box // Right
{
 < 0.21, 0.0, 0.0 > < 0.204, 0.93, 0.26 >
 texture { MyGlass }
}

box // Bottom
{
 < -0.21, 0.0, 0.0 > < 0.21, 0.006, 0.26 >
 texture { MyGlass }
}

box // Top
{
 < -0.21, 0.924, 0.0 > < 0.21, 0.93, 0.26 >
 texture { MyGlass }
}

box // Balcony Bottom
{
 < -0.21, 0.80, 0.18 > < 0.21, 0.806, 0.26 >
 texture { MyGlass }
}

box // Balcony Front
{
 < -0.21, 0.80, 0.18 > < 0.21, 0.85, 0.186 >
 texture { MyGlass }
}

box // Front Top Border
{
 < -0.21, 0.886, 0.04 > < 0.21, 0.93, 0.046 >
 texture { MyGlass }
}

box // Front Bottom Border
{
 < -0.21, 0.0, 0.04 > < 0.21, 0.106, 0.046 >
 texture { MyGlass }
}

box // Front Bottom Front
{
 < -0.21, 0.0, 0.0 > < 0.21, 0.046, 0.006 >
 texture { MyGlass }
}

box // Bottom Pool Left
{
 < -0.056, 0.0, 0.04 > < -0.05, 0.106, 0.26 >
 texture { MyGlass }
}

box // Bottom Pool Right
{
 < 0.056, 0.0, 0.04 > < 0.05, 0.106, 0.26 >
 texture { MyGlass }
}

box // Front Door
{
 < 0.5, 0.0, -0.1 > < 0.92, 0.93, -0.094 >
 texture { MyGlass }
}

difference
{
 union
 {
  torus { 0.05, 0.01 rotate < 0.0, 0.0, 90.0 > translate < 0.60, 0.65,
-0.1 > }
  torus { 0.05, 0.01 rotate < 0.0, 0.0, 90.0 > translate < 0.82, 0.65,
-0.1 > }
 }
 box { < 0.5, 0.55, -0.1 > < 0.92, 0.75, 0.05 > }
 pigment { rgb < 0.9, 0.9, 0.95 > }
 finish { reflection 0.9 metallic 0.5 }
}

cylinder // Ground
{
 < 0.0, -0.1, 0.0 > < 0.0, -0.0001, 0.0 > 1.0
 pigment
 {
  spherical
  color_map
  {
   [ 0.00 rgb  < 0.50980, 0.52157, 0.99216 > * 0.525 ]
   [ 1.00 rgb  2.0 ]
  }
  rotate < 0.0, 0.0, 0.0 >
 }
 translate < 0.2, 0.0, 0.2 >
}

Post a reply to this message