|
![](/i/fill.gif) |
And a view at altitude 10 km. I put Tethys and Titan a little bit higher
than the plane of the ring for artistic reasons.
Note that the ring material is composed of two isosurfaces, one for the
finer fraction (only a crackle function) and one for the coarser
fraction. Additionally 3 million rocks form the coarsest fraction.
Isosurfaces'code:
//----------------------------------------------------------------------
//Isosurface for the finer ring elements (thanks to Christian Froeschlin)
#declare f_particles =
function(x,y,z) {
0.8
- f_crackle(400*x, 400*y, 400*z)
+ f_bozo(x*100, y*100, z*100)
- f_waves(x*100+f_bozo(x*100,0,0), y*10+f_bozo(0,y*10,0),
z*100+f_bozo(0,0,z*100))
}
#declare f_fineparticles =
function(x,y,z) {0.7 - f_crackle(x*800, y*800, z*800)}
intersection {
union {
isosurface {
function {f_particles(x,y,z)}
contained_by {
box {<0.00, -0.5*0.01, -117581.00*0.001>, <117581.00*0.001,
0.5*0.01, 117581.00*0.001>}
}
accuracy 0.0001
max_gradient 1000
texture {
pigment {srgb <0.96, 0.96, 0.98>*0.75}
finish {diffuse 0.8 specular 0.2 roughness 0.001}
}
}
isosurface {
function {f_fineparticles(x,y,z)}
contained_by {
box {<0.00, -0.4*0.01, -117581.00*0.001>, <117581.00*0.001,
0.4*0.01, 117581.00*0.001>}
}
accuracy 0.0001
max_gradient 1000
texture {
pigment {srgb <0.94, 0.94, 0.90>*0.5}
finish {diffuse 0.8 specular 0.2 roughness 0.001}
}
}
}
difference {
cylinder {<0, -1, 0>, <0, 1, 0>, 117580.00*0.001}
cylinder {<0, -1.1, 0>, <0, 1.1, 0>, 92000.00*0.001}
}
hollow
}
--
Thomas
Post a reply to this message
Attachments:
Download 'complex_08.png' (940 KB)
Preview of image 'complex_08.png'
![complex_08.png](/povray.binaries.images/attachment/%3C54b53671%40news.povray.org%3E/complex_08.png?preview=1)
|
![](/i/fill.gif) |