|
|
On 8-10-2014 20:53, Bald Eagle wrote:
> Whatever's going on, my floor is NOT coming out anywhere close to the rich honey
> yellow of the reference photo.
Try this. I believe it comes closer to what you want:
#local Tone = <1.2, 1.2, 0.3>;
#declare OakFloor =
texture {
pigment {
wood
color_map {
[0.0 srgb <121, 52, 13>/255 * Tone]
[0.2 srgb <142, 73, 18>/255 * Tone]
[0.4 srgb <184, 115, 48>/255 * Tone]
[0.6 srgb <157, 81, 23>/255 * Tone]
[0.8 srgb <108, 45, 4>/255 * Tone]
[1.0 srgb <156, 72, 26>/255 * Tone]
}
warp {turbulence <0.6, 0.1, 0.1>}
scale <1, 1, 10>*0.5
scale 0.3
rotate 1*x
rotate y*10
}
}
You could also experiment with the following texture by Nicolas Rougier,
which is an excellent wood texture:
//============= NR_Wood (2003) =============
#declare NR_wood_grain =
pigment {
wood
warp {cylindrical orientation y dist_exp 1}
warp {turbulence 1.25}
scale <.5,30,1>
warp {turbulence .25}
scale <1,10,1>
warp {
black_hole <0, 0.5, 0>, 1
falloff 2
strength 1.5
repeat 7
turbulence 2
inverse
}
}
#declare NR_wood_normal =
function {
pigment {
wood
warp {cylindrical orientation y dist_exp 1}
warp {turbulence 1.25}
scale <.5,30,1>
warp {turbulence .25}
scale <1,5,1>
color_map {[0 rgb <0,0,0>] [1 rgb <1,1,1>]}
}
}
#declare NR_woodmap =
color_map {
[0.00 srgb <0.949, 0.792, 0.514 >]
[0.30 srgb <0.855, 0.651, 0.376 >]
[0.60 srgb <0.831, 0.596, 0.275 >]
[0.90 srgb <0.620, 0.447, 0.204 >]
}
#declare NR_Wood =
texture {
pigment {NR_wood_grain
color_map {NR_woodmap}
ramp_wave
}
normal {
function {NR_wood_normal(x,y,z).grey*0.5
}
}
finish {diffuse 0.6 specular 0.1 roughness 0.005}
}
Thomas
Post a reply to this message
|
|