I posted an image in p.b.i.

Forgive me for having changed a couple of things in your code in 
addition to those mentioned earlier ;-)

1- I made the code 3.7 ready by adding the #version, assumed_gamma, and 
radiosity settings I am familiar with;

2- I changed rgb to srgb. Not essential but it deepens the colours of 
the textures;

3- I changed somewhat the sun code:
#include "CIE.inc"  // for SunColor. Comes with Lightsys IV
#declare SunColor   = Blackbody(6500)*3;
#declare SunAlt     = 60;
#declare SunAzm     = -120;
#declare SunPosition  = <0, 0, -1>*10e6;
#declare SunDis     = vlength(SunPosition)*2/215;

#declare sun =
light_source {
   SunPosition
   color SunColor
   rotate x*SunAlt
   rotate y*SunAzm*clock
   parallel
/*
   area_light
   SunDis*x, SunDis*z,
   5, 5                // total number of lights in grid
   adaptive 1          // 0,1,2,3...
   jitter              // adds random softening of light
   circular            // make the shape of the light circular
   orient              // orient light
*/

   looks_like {sphere {0, 1001 pigment {color SunColor} finish {emission 
1}}}
}

object {sun}

4- I changed the landscape material. See also the slope documentation in 
particular for Hi_slope and Lo_slope. I first made the material into a 
macro:
#macro land_material(Min,Max)
material {
   //rock
   texture {
     pigment {
       bozo scale 450 turbulence 2
       color_map {[0 srgb 0.3][0.5 srgb 0.5][1 srgb 0.8]}
     }
     finish {diffuse 0.6}
     normal {granite 0.8 scale 0.01}
   }

   //moss
   texture {
     pigment {
       slope {<0,-0.9, 0>, 0.0, 0.5 altitude <0, 0.1, 0>, Min.y, Max.y}
       pigment_map {
         [0.3 srgbt 1]
         [0.3 bozo scale 54
             pigment_map {
               [0 bozo scale 0.2 turbulence 1 color_map {[0 srgb <0.5, 
0.6, 0.25>*4 ][1 srgb <0.5, 0.8, 0.1>]}]
               [0.5 bozo scale 0.05 turbulence 1 color_map {[0 srgb 
<0.5, 0.55, 0.3>][1 srgbt 1]}]
             }]
       }
     }
     finish {diffuse 0.8}
     normal {granite 0.1 scale 0.01}
   }

   //snow
   texture {
     pigment {
       slope {<0, -0.5, 0>, 0.0, 0.5 altitude <0, 0.5, 0> Min.y, Max.y }
       color_map {[0.5 srgbt 1][0.55 srgb 2]}
     }
     finish {diffuse 1 brilliance 0.1 specular 0.5 roughness 0.002}
     normal {granite 0.5 scale 0.005}
   } 

}
#end

Then I commented out the material in the land object, and added after it:
#declare Min = min_extent(land);
#declare Max = max_extent(land);

#declare land =
object {land
   land_material(Min,Max)
}

See the resulting image in p.b.i.

Thomas

Post a reply to this message