High!

Smws wrote:
> I have been lurking on these newsgroups for a little while now, and since I have
> been raytracing again I thought I would post something.
> 
> I've been working with pseudorandom landscape generation --seemingly a phase
> many people go through :) and here is one of the more interesting landscapes
> that I have come across so far. Sorry for the very boring texture, no other
> objects, etc.
> 
> function pattern dents - function pattern granite

Interesting... as I myself started tinkering with a whole isosurface 
planet, I would like to know how you combined the two functions, i. e. 
what amount and scale for each!

My isosurface landscape (see below) currently is a combination of

x*x + y*y + z*z -1 for overall spherical shape of the planet,
granite, scaled to 10 and using a poly_wave with exponent 0.3333 for the 
mountain ridges, finally
bozo for large-scale variance of elevation

The amount (multiplication factor within the combined isosurface) of 
granite is 0.02, of bozo is 0.01.

Here my code:

#declare Terrain_Part1_Function=
function
{
   pattern
   {
     granite
     scale 10
     poly_wave 0.333
   }
}

#declare Terrain_Part2_Function=
function
{
   pattern
   {
     bozo
   }
}

#declare S =
function { x*x + y*y + z*z -1 }

#declare Ghurghusht =
union
{
   isosurface
   {
     function { S(x, y, z) + Terrain_Part1_Function (x*50, y*50, 
z*50)*0.02 + Terrain_Part2_Function (x, y, z)*0.01 } // f_noise3d 
(x*100, y*100, z*100)*0.007 }
     contained_by { sphere { 0, 1 } }
     max_gradient 10
     accuracy 0.0001
     texture
     {
       pigment { color rgb <0.98, 0.85, 0.45> }
       finish { ambient 0.05 diffuse 1 brilliance 0.98 }
     }
   }
   scale 5178 // radius in kilometres
}

Currently, I have not yet rendered a close-up surface view in 
"pedestrian" perspective (only a close-up of the planet's limb at the 
equator, see last image)... but I think I'll replace that simple granite 
function later on by ridged_mf or a similar more sophicisticated 
function to get wider lowlands at 0 to 200 metres elevation around the 
lakes (see cylindrical map). Then there is also the problem of modelling 
realistic erosion/drainage patterns...

See you in Khyberspace!

Yadgar

Post a reply to this message

Attachments:
Download '2010-01-24 ghurghusht, lakes hemisphere, take 1.jpg' (180 KB) Download '2010-01-26 ghurghusht, highland hemisphere, take 1.jpg' (146 KB) Download '2010-02-05 cylindrical map of ghurghusht, take 3.png' (935 KB) Download 'ghurghusht0186.png' (348 KB)

Preview of image '2010-01-24 ghurghusht, lakes hemisphere, take 1.jpg'

Preview of image '2010-01-26 ghurghusht, highland hemisphere, take 1.jpg'

Preview of image '2010-02-05 cylindrical map of ghurghusht, take 3.png'

Preview of image 'ghurghusht0186.png'