"mhc91" <nomail@nomail> wrote in message 
news:web.4a64b0da304dff418e079a6f0@news.povray.org...
> hello, I'm a new user and for a project in class we're creating a scene of 
> our
> choice, I want to create a scene of a storm, with lightning hiting the 
> ground,
> a tornado and storm clouds in the sky. How could I create this?
> thank you
>

As Alain said, this is ambitious for someone new to POV-Ray, but that's not 
necessarily a bad thing, it depends how much time and energy you've got.

I'd say that there are some easier approaches than using media, although 
media would probably give the best results, I would argue that it's easier 
to learn if you keep the render times as short as possible, so that you can 
do more test renders.

There are various tutorials for creating clouds on the Internet, though 
storm clouds are likely to be quite tricky. The example below just uses a 
simple 'wrinkles' pattern with turbulence for the clouds (but doesn't look 
very stormy)l.

For the lightning I'd recommend butting together some simple thin cone 
shapes. Turn the ambient setting up high for the lightning cones and down 
for everything else to give quite a moody feel.

The simple example below may serve as a starting point. It uses 3 white 
cones with ambient turned up high. There are 5 lights distributed up the 
middle of the lightning object using 'fade' settings to prevent the light 
from travelling very far. The no_shadow keyword on the lightning object 
enables light to pass out and prevents the cones from casting shadows on 
other objects in the scene.

I've used RGB values to specify colours here. If you prefer to use the names 
of predefined colours you should add:

#include "colors.inc"



camera {location <0, 1, -5> look_at <0,2,0>}
#declare MyLightSource = light_source {<0,0,0> color rgb 2
  fade_distance 0.4
  fade_power 2
}

// Lightning
union {
  cone {<0,0,0>,0.00,<3,3,3>,0.02}
  cone {<3,3,3>,0.01,<1,6,1>,0.03}
  cone {<2,1,0>,0.00,<2,2,2>,0.01}
  no_shadow
  pigment {rgb 1}
  finish {ambient 2}
}

// Lights inside the lightning object
light_source {MyLightSource}
light_source {MyLightSource translate <1,1,1>}
light_source {MyLightSource translate <3,3,3>}
light_source {MyLightSource translate <2,1,0>}
light_source {MyLightSource translate <1,5,1>}


// Ground
plane {y,-0.1 pigment {rgb <0,0.2,0>} finish {ambient 0}}

// Sky
plane {y,5.2
  finish {ambient 0}
  pigment {
    wrinkles
    turbulence <0.5, 0.5, 0.5>
    octaves    7
    omega      0.5
    lambda     3
    color_map {
      [0.0 color rgb <1.00,1.00,1.00>]
      [0.4 color rgbt 1]
      [0.5 color rgbt 1]
      [1.0 color rgb <1.00,1.00,1.00>]
    }
  }
}




Regards,
Chris B.

Post a reply to this message