Very nice way to waste time...
Blender image has perhaps better lights, but I like a lot your cups.
;-)
Paolo

 >nemesis wrote:
> so, any free time in your hands?  want to put that quad core to stress with
> povray 3.7beta?  If you're, try the little scene below.  With +AM2 +A0.04 +J1.0
> 1024X768 on a P4 2.66, it just brought my PC to a crawl for the whole weekend!
> It all began with a challenge in a brazilian forum, when some guy claimed this
> scene:
> http://200.213.105.41/greysilica/exemplos/cjcopojateado.png
> 
> took him 48 hours to render with Blender internal renderer.
> 
> Surely something was wrong, or so I thought.  Well, in the region between the
> bottom of second row cups and the top of first row cups, render time was about
> 11 minutes a line!  It is all about refractions, normals and fresnel
> reflections.  40 hours total on a P4 2.66 with povray 3.6.1...
> 
> I'm sure it's possible to optimize it with some no_image, no_shadow trickery
> with doubles and no_reflection in the main cups, but I didn't thought of it
> beforehand!
> 
> 
> global_settings { max_trace_level 40 }
> 
> background { rgb 1 }
> 
> #local cup =
> lathe { bezier_spline
> 48, //nr points
> /* 0*/ <0, 2.8571826>, <174.28571, 2.8571826>, <197.14286,2.8571826>,
> <197.14286,2.8571826>,
> /* 1*/ <197.14286, 2.8571826>, <197.14286, 2.8571826>, <211.42857,-2.8571174>,
> <228.57143,14.285683>,
> /* 2*/ <228.57143, 14.285683>, <245.71429, 31.428583>, <242.85714,85.714283>,
> <242.85714,85.714283>,
> /* 3*/ <242.85714, 85.714283>, <242.85714, 85.714283>, <265.71429,80.000003>,
> <291.42857,105.71428>,
> /* 4*/ <291.42857, 105.71428>, <317.14286, 131.42857>, <308.57143,108.57143>,
> <308.57143,185.71428>,
> /* 5*/ <308.57143, 185.71428>, <308.57143, 262.85714>, <308.57143,742.85714>,
> <308.57143,742.85714>,
> /* 6*/ <308.57143, 742.85714>, <308.57143, 742.85714>, <317.14286,737.14285>,
> <308.57143,754.28571>,
> /* 7*/ <308.57143, 754.28571>, <300, 771.42857>, <288.57143,780>,
> <280,768.57143>,
> /* 8*/ <280, 768.57143>, <271.42857, 757.14285>, <294.28571,165.71428>,
> <277.14286,148.57143>,
> /* 9*/ <277.14286, 148.57143>, <260, 131.42857>, <231.42857,131.42857>,
> <217.14286,105.71428>,
> /* 10*/ <217.14286, 105.71428>, <202.85714, 80.000003>, <205.71429,54.285713>,
> <185.71429,45.714283>,
> /* 11*/ <185.71429, 45.714283>, <165.71429, 37.142883>, <2.8571429,2.8571826>,
> <0,2.8571826>
> 
> sturm
> scale y*.8
> scale 1/1000
> interior { ior 1.5 }
> hollow
> }
> 
> #macro tex( col )
> pigment { rgb col }
> normal { bumps .1 scale .002 }
> finish { ambient .01 diffuse .4 brilliance 1.2
> specular .97 roughness .02
> metallic .1
> reflection { .2,.9 metallic .1 fresnel on exponent 1 }
> conserve_energy
> }
> #end
> 
> union {
> plane { y 0 pigment { rgb 1 } finish { ambient .2 diffuse .6 } }
> object { cup translate 0 tex( <.7,.8,1,.8,.1> ) }
> object { cup translate z*.7 tex( <.9,.86,.4,.8,.1> ) }
> object { cup translate z*(.7+1.3) tex( <1,.96,.84,.8,.1> ) }
> object { cup translate x*.7 tex(<1,1,1,.8,.1> ) }
> object { cup translate x*.7+z*.7 tex(<.96,1,.67,.8,.1> )}
> object { cup translate x*.7+z*.7*2 tex(<.7,1,.7,.8,.1> ) }
> object { cup translate -x*.7 tex(<1,.6,.6,.1,.8> ) }
> object { cup translate -x*.7+z*(.0+1.3) tex(<.5,.5,.8,.1,.8> ) }
> object { cup translate -x*.7*2+z*(-.7+1.3) tex(<.7,1,.94,.1,.8> ) }
> light_source { 1.6*(4-z*8) 1.2 }
> 
> rotate -x*30
> translate z*2.6-y/3+x*.1
> }
> 
> light_source { -z*8 .7 shadowless }
> 
> camera { angle 55
> //aperture .04 blur_samples 60 confidence 1 focal_point y/3+z*2
> }
> 
> 
> ------------------------------------------------------------------------
>

Post a reply to this message