there you go.  You can find the bunny model in my scene 
radiosity_and_bunnies.  I posted the source in 
povray.binaries.scene-files...

You know, ridiculously low error_bound values don't really help much. 
Fiddling with lower pretrace steps gives far better results IMO...


#local HQ = 0;
#local GI = 1;
#local GIgather = 0;
#local CAD = 0;
#local CAMS = 1;

#if (GI)
#local LF = .5;
#else
#local LF = 1.1;
#end

global_settings {
    #if (GI)
    radiosity {
        brightness 1.2
        always_sample no
        #if (!GIgather)
            load_file "bunny.rca"
        #else
            save_file "bunny.rca"
            #if (HQ)
            count 200*4 //1400
            error_bound .2
            low_error_factor .2
            adc_bailout .01/.4
            nearest_count 14
            recursion_limit 3
            #else
            count 80*10
            error_bound .2
            adc_bailout .01/.7
            low_error_factor .2
            nearest_count 18
            recursion_limit 3
            #end
        #end

        pretrace_start .04
        pretrace_end .006
        gray_threshold .7
    }
    #else
    ambient_light 1.4
    #end
}


background { rgb 0 }


union {
    plane { y, 0 pigment { rgb 1 } finish {ambient 0} }
    #if (0)
    sphere {y*.7,.7 
        texture {
            //pigment {rgb 1} 
                pigment{ marble turbulence 1.2 octaves 5 lambda 4 scale 
1.4 color_map {[0 rgb 1][.7 rgb 1][.77 rgb .8][1 rgb .6]} }
            finish {ambient 0 diffuse .62}
        }
    }
    #else
    object {#include "meshstandford_bunny.inc" scale 10 rotate -y*120 
translate -y*.08 }
    #end
    #if (!GI)
    light_source { 20*(4-z*8) .8
        #if (HQ)
        area_light x*50,z*50,18,18 jitter adaptive 0 circular orient
        #end
    }
    light_source { 20*(4-z*4) .8
        #if (HQ)
        area_light x*60,y*60,18,18 jitter adaptive 0 circular orient
        #end
    }
    #else
    box { -30, 30 translate 20*(4-z*8) pigment {rgb 1} finish { ambient 9 
diffuse .8 } }
    box { -30, 30 translate 20*(4-z*4) pigment {rgb 1} finish { ambient 9 
diffuse .8 } }
    #end
 
    rotate -y*50
    rotate -x*20
    translate z*3-y/2
}

#if (!GI)
light_source { -z*2+y/3+x .56 shadowless }
#end

camera { aperture .2 blur_samples 40 focal_point y*.15+z*2.2 }

Post a reply to this message

Attachments:
Download 'us-ascii' (7 KB)