> How do I achieve oblique projection using POV-Ray? I've tried messing 
> around
> with the up and right vectors, but have achieved mixed results.

POV 3.6 doesn't support an oblique camera, as close as you will come
is the orthographic camera. However, you can deform your scene
by skewing it with Shear_Trans from transforms.inc, this should
get the same look if used in conjunction with an orthographic camera.

MegaPOV has a user defined camera, you might be able to
define an oblique camera there, but I haven't tested it.

#version 3.6;

#include "colors.inc"
#include "transforms.inc"

camera {
   orthographic
   location  <0.0, 0.3, -2.0>
   direction z
   right     x*image_width/image_height
   up y
   look_at   <0.0, 0.1,  0.0>
}

background {White}

light_source {
  <-10, 30, -30>
  color rgb <1, 1, 1>
}

light_source {
  <20, 30, -30>
  color rgb <0.2, 0.2, 0.4>
  shadowless
}

#declare blgs = union {
 box {<0,0,0>,<0.2,0.2,0.2>}
 box {<0,0,0.3>,<0.2,0.3,0.5>}
 box {<0,0,0.6>,<0.2,0.2,0.8>}
 pigment {White}
};

#declare scene = union {
 plane {y,-0.001
    pigment{hexagon Yellow*0.5 LimeGreen ForestGreen scale 0.05}
 }
 object {blgs translate <-0.5,0,0>}
 object {blgs translate <-0.2,0,0>}
 object {blgs translate <0.1,0,0>}
}

object {
   scene
   Shear_Trans(<1,0,0>,<0,1,0>,vnormalize(<0.1,0.1,1>))
}

Post a reply to this message