Charles nous apporta ses lumieres en ce 2007/09/02 17:18:
> Dear Everyone,
> 
> Burki: even though your candle looks very nice, it still doesn't render
> embedded objects with "participating" wax. I think (read: fear) that what I
> need is a full volume render, which
> 1) takes ages to render;
> 2) I don't know if povray is capable of.
> 
> What seems to be the problem is that POVRay treats a material as a single
> entity instead of rendering it as thousands if not millions of particles
> (think of smoke). The obvious solution here is a #while-loop to dynamically
> generate as many of these micro-particles as gives a good render result.
> This post is a last cry for something more decent. Some sort of mapping?
> 
> Thanks,
> Charles
> 
> PS. Alain, I'm not sure this is what your code attempts to do. I couldn't
> get it parsed (latest POVRay version).
> 
> 
> 
> 
Where is the error? And what does it say?
Try this one:

#include "colors.inc"

global_settings {
   assumed_gamma 1.0
   max_trace_level 5
   photons{spacing 0.1}
}

// ----------------------------------------

camera {
   location  <0.0, 0.5, -4.0>
   direction 1.5*z
   right     x*image_width/image_height
   look_at   <0.0, 0.0,  0.0>
}

sky_sphere {
   pigment {
     gradient y
     color_map {
       [0.0 rgb <0.6,0.7,1.0>]
       [0.7 rgb <0.0,0.1,0.8>]
     }
   }
}

light_source {
   <0, 0, 0>            // light's position (translated below)
   color rgb <1, 1, 1>  // light's color
   translate <-30, 30, -30>
}

// ----------------------------------------

plane {               // checkered floor
   y, -1
   texture
   {
     pigment {
       checker
       color rgb 1
       color blue 1
       scale 0.5
     }
     finish{
       diffuse 0.8
       ambient 0.1
     }
   }
}

#declare Obj_Col = <1, 0.6, 0.2>;
#declare Obj_Absorption = 1 - Obj_Col;
#declare Media_Density = 7;    //was 6.5; // must be adapted to size
#declare SSS_Tex =
      texture {
           pigment {
                rgb Obj_Col
                filter 1.2 // was 1.0
           }
           finish {
                brilliance 4 // wasn't included from Andy Cocker
                specular 0.5
                roughness 0.2
                ambient 0.2
                reflection {
                     0.0,
                     0.5
                     fresnel
                }
                conserve_energy
           }
	normal{ granite 0.2 scale 0.00041}
      }
#declare SSS_Int =
      interior {
           ior  1.3 // close to water
           // Media with absorption and scattering
           media {
                absorption Obj_Absorption*2
                scattering {
                               4, // Rayleigh
                               Media_Density //see above
                }
           }
      }

#declare SSS_Material =
material {
      texture {
           SSS_Tex
      }
      interior {
           SSS_Int
      }
}



//
cylinder{
      <0, -1, 0>
      <0, 0.3, 0>
      0.3
      hollow
      material {SSS_Material}
      //photons{target refraction on}
}
sphere{<-0.1, -0.3, -0.1>,0.1 pigment{rgb 0}}
// an imbeded black sphere.
//end of file


-- 
Alain
-------------------------------------------------
Just because someone doesn't love you the way you want them to, doesn't mean 
they don't love you with all they have.

Post a reply to this message