"carleton" <nomail@nomail> wrote in message 
news:web.46b9a2d26c254cfe326f2a60@news.povray.org...
> Hi folks, I am starting a one man software company and am looking for a
> logo.  I saw this the other day:
>
> http://www.phplivesupport.com/pics/screenshots/setup_trackit.gif
>
> and realized it was EXACTLY what I was looking for, except rather then a
> dollar sign, I wanted two capital letter P's.  Years back (around 1992) I
> played with povray and thought it would be the ideal tool to create such a
> graphic, but it has been so long I thought I might see if anyone here 
> might
> be able to help me setup on a script to create something basic like this.
>
> Carleton
>

camera {
 location <0.7,1.25,-1.25>
 look_at 0.3*y
}
light_source { <-3, 10, -3> color rgb 1 }
light_source { <0, 0.3, 1> color rgb 1 }


#declare Arrow = union {
  // Arrow Head
  difference {
    box {<0,0.47,0><1,0.53,1>}
    plane { x,0 rotate  30*y translate x*0.35}
    plane {-x,0 rotate -30*y translate x*0.65}

  }
  // Shaft
  difference {
    cylinder {y*0.47,y*0.53,0.55}
    cylinder {0,y,0.45}
    box {0,1}
  }
  texture {
    pigment { color rgb <136,183,235>/300}
    finish {ambient 0.6}
    normal {agate 0.4 scale 0.01}
  }
}

#declare P = text {
  ttf
  "crystal.ttf",
  "P",
  0.1,
  0
  texture {
    pigment { color rgb <52,108,171>/220}
    finish {ambient 0.6}
    normal {agate 0.4 scale 0.01}
  }
}

object {Arrow no_shadow rotate -y*20 translate -y*0.1}
object {P translate -0.4*x}
object {P translate -0.02*x}

plane {y,0
  texture {
    pigment {color rgb 1}
    finish {ambient 0.3}
    normal {agate 0.04 scale 0.05}
  }
}

Post a reply to this message