>I nothing understand. I tried to change every value. But nothing helps. (;

There's nothing distictly "wrong", but if you are looking for something
like Mnesia's picture there's a long way to go...

> global_settings
> {
>  max_trace_level 100 /*or another high number*/
>  adc_bailout 1/127 /*decrease the denominator for faster but less exact
>  results*/
> }

max_trace_level isn't the culprit here, this should work fine at the
default, but keep it in mind for later as you add other height_fields.

> #include "colors"
> light_source {
>   <45, 33, -50>, rgb <1, 1, 1>
> }

This is good, a light to see things... but what I don't see is
a background or a sky_sphere, glass objects will reflect
and refract the color from here, so the more intresting this
is the better the image will end up.

> height_field {
>   png "/home/mike/povray/povray-test.png"
>   water_level 0.0001

Water level... hmm, so now you have a surface
with an interesting edge, but no back surface, in some
cases like islands where you can't see the back that is
OK, but you will see it because glass is clear. What
you really want is something like a difference...
difference{height_field{...} box{<0,0.001,0>,<1,1,1>}
That way you will have a flat back surface...
If you want the back to be an inverted copy of the
front surface, then could #declare your height_field then
merge a flipped copy...
#declare myhf = difference{height_field{...}box{...inverse}
translate -0.0015*y};  //overlap them
merge{object{myhf}object{myhf scale -y}}

>   scale 1
>   no_shadow
>   hollow false
>   rotate x*(-90)
>   translate <-0.5, -0.5, 0>

The order here is awkward... first center your
object at the origin, then rotate and scale...
that way if you change the scale you don't need
to change the numbers for the translate. Also
"hollow off" is the default. Typically it is clearer
to just use "hollow" or don't.

>   material {...
Nothing wrong with the texture really, but it
has a bit high transparency, and a bit low
reflection.

>//here is another tweak of these fractal.

An image of the color version
that's a good refererence I guess...

>camera {
>   orthographic

Are you sure you really want a flat orthographic camera?
that can make it hard to see the depth.

#include "glass.inc"
sky_sphere {
  pigment {
    gradient y
    color_map {
       [0.0 White]
       [0.25 Orange]
       [0.5 White]
       [0.75 NavyBlue]
       [1.0 White]
    }
  }
}
#declare myglass =  material{
   texture {
      pigment {Col_Glass_Orange}
      finish{F_Glass5}
   }
   interior{I_Glass1}
};
#declare flhf = height_field {
   png "E:\graphics\render\fractal.png"
   smooth
};
#declare flhf2 = difference{
   object {flhf}
   box{<0,0.35,0>,<1,1,1> inverse}
   translate <-0.5,-0.35,-0.5>
};
#declare flhf3 = merge{
   object{flhf2}
   object{flhf2 scale -y translate 0.001*y}
};
object{flhf3
   material{myglass}
   rotate <-90,0,0>
}

Post a reply to this message