I looked at your code...

I think you have parts of the media object in
a non-hollow object.

Parts of your scene have no texture assigned.

The sky_sphere, background and fog don't work
well with media (3.3.2.1). Use a big inverted
sphere or something for sky.

The scale of your objects is quite large, the
clouds in particular are at the edge of the
resolution of the floating point numbers in pov.
I tend to use 1 pov unit = 1 foot or so...

Here's a similar scene I made tests with...

--- Code ---
// Persistence of Vision Ray Tracer Scene Description File
// File: stained.pov
// Vers: 3.6
// Desc: a test of stained glass and media
// Date: 12/20/2006
// Auth: Tim Attwood
//

#version 3.6;

#include "colors.inc"
#include "stones.inc"

global_settings {
  assumed_gamma 1.0
}

// --- camera, lights & background ----------------------------------------

camera {
   location  <2.5, 0.7, -4.0>
   direction 1.5*z
   right     x*image_width/image_height
   look_at   <1.0, 0.0,  0.0>
}

light_source {
  <-30, 40, 30>
  color rgb <1, 1, 1>
}

light_source {
  <5, 5, -30>
  color rgb <.1, .1, 1>*0.2
  media_interaction off
}

// --- textures -----------------------------------------------------------

#declare Stained_Glass = texture {
   pigment {
      crackle solid
      color_map {
         [0 Red transmit 0.1 filter 0.8]
         [0.2 Yellow transmit 0.1 filter 0.8]
         [0.4 Blue transmit 0.1 filter 0.8]
         [0.6 Red transmit 0.1 filter 0.8]
         [0.8 Yellow transmit 0.1 filter 0.8]
         [1 Orange transmit 0.1 filter 0.8]
      }
      scale 0.2
   }
}
texture {
   pigment {
      crackle
      color_map {
         [0 Black]
         [0.02 Black]
         [0.03 Clear]
         [1 Clear]
      }
      scale 0.2
   }
};

#declare Dust = material {
    texture {
       pigment {Clear}
    }
    interior {
       media {
         scattering {
            2, 0.07 extinction 0.01
         }
         method 3
         samples 30,100
       }
    }
};

#declare Wall = texture {
   pigment {
      brick Gray50,Firebrick
      scale 0.025
   }
};

#declare Floor = texture {
    hexagon
    texture { pigment{Tan*0.9} },
    texture { pigment{Tan} },
    texture { T_Stone17 scale 3}
    scale <0.4,1,0.2>
};

// --- scene --------------------------------------------------------------

// floor
plane {y,-1 texture {Floor}}

// windows
union {
   box {<-2,0,2>,<-1,1.6,2.001>}
   box {<-0.8,0,2>,<0.2,1.6,2.001>}
   box {<0.4,0,2>,<1.4,1.6,2.001>}
   texture {Stained_Glass}
}

//wall
difference {
   box {<-10,-1,1.8>,<10,10,2.2>}
   box {<-2,0,0>,<-1,1.6,3>}
   box {<-0.8,0,0>,<0.2,1.6,3>}
   box {<0.4,0,0>,<1.4,1.6,3>}
   texture {Wall}
}

// sky
sphere {<0,0,0>,100 inverse pigment {White}}

// media object
box {
   <-2,-1,-1>,<4,1.6,1.999> hollow
   material {Dust}
}

Post a reply to this message