"Quartz" <nomail@nomail> wrote in message
news:web.442c0a2541c1995dfd52120@news.povray.org...
> Hello, everyone. I've been using POVRay for 5-10 of the 13 years that I've
> lived now, and I ran into a great buttress of a problem with the scene I've
> been recently working on. This problem is so unusual that I'm now executing
> what I had earlier held as a last resort: registering here on the newsgroup
> to ask you people (Don't worry, it's nothing personal. ;-) ).
>
> Here's my problem. I have the camera in a dark room, facing a window. I need
> heavy rain on the outside of the window, and a lightning flash shining in
> through the window.
>
> I tried an excessively bright point light outside the window for the
> lightning, and I tried reflection with a bozo normal _on_ the window for
> the rain, but those both take it in the entirely wrong direction. I sifted
> through the tenuousness of Google searches already, but I uncovered nothing
> save Chambers' dandelion
>
(http://news.povray.org/povray.binaries.images/thread/%3C43fe52d0@news.povray.or
g%3E/).
> The problems with following how Chambers
> accidentally made it look like rain on the window are various:
>  1): His looked like light rain, not heavy rain.
>  2): His window was at a tight angle, and mine is straight on. I imagine
> that would make a difference.
>  3): He has things outside the window in the background, whereas I have
> nothing but the lightning flash.
>
> Can any of you help me figure out how to go about this?

Do you mean you want the lightning flash to "light up" the rain on the window?

If so, the main thing that causes this to happen in real life is of course all
of the tiny droplets refracting the lightning strike, so with that in mind you
need a very strong normal or an isosurface that models the thousands of
droplets, and then a very bright object to refract, as well as a bright light to
create specular highlights on all of the droplets.

In this example a big white box represents the visible lightning, and a light
adds to the specular highlights on the (poorly modelled) rain drops.  (render
with AA enabled)

camera {location <0,0,-3> look_at <0,0,0>}
light_source {<-5,3,-10> rgb <0.8,0.8,1>*10}
box {<-1,-1,-0.05> <1,1,0>
 texture {
  pigment {color rgbf <1,1,1,0.7>}
  finish {specular 1 roughness 0.001 ambient 0 diffuse 0 reflection 0.1}
  normal {
   bumps
   slope_map {
    [0 <0,0>]
    [0.95 <0,1>]
    [1 <0.1,1>]
   }
  }
  scale <0.02,.1,.1>*.3
  rotate <45,0,0>
 }
 interior {ior 1.5}
}
box {<0,5.1,4> <-10,30,7>
 texture {
  pigment {
   gradient x
   color_map {
    [0 color rgb 1]
    [.7 color rgb <0.5,0.5,1>]
   }
  }
  finish {ambient 80}
 }
}


I hope this helps...

Cheers,

Lance.

thezone - thezone.firewave.com.au

Post a reply to this message