Ger wrote:

> "StephenS" <sshonfield(at)ottawa(dot)net> wrote:
> 
>> 
>> I've been giving this some thought, I may try it later. The building only
>> has windows on two sides, several walls and shelves of material block
>> large portions of the interior from direct sunlight. "rows of overhead
>> point lights, emulating the fluorescent tubes" is the part I'm struggling
>> with. There are approximately 14 rows of 10, 8 foot double fluorescent
>> tubes, with most pieces of equipment having one or more additional light
>> fixtures hanging from the ceiling. Any suggestions on how many point (or
>> maybe spot) lights per fixture I should use?
>> 
>> Stephen
> 
> This is what I used a while back in a project I was working on
> #declare the Lights variable however high/low you want it. Just keep in
> #mind
> that this is a multiplier
> 
> #if ( Final )
>         #declare Lights = 5; // Makes a total of 11 lights per TL-lamp
> #else
>         #declare Lights = 0; // Just 1 light for preview purposes
> #end
> 
> #macro TL_Bak(OnOff)
> union {
>         box {< -25 , 0 , -500 >,<  25 , 70 , 500> pigment { White }}
>         box {< -15 , 0 , -500 >,<  15 ,-25 ,-475> pigment { White }}
>         box {< -15 , 0 ,  500 >,<  15 ,-25 , 475> pigment { White }}
>         cylinder {<0,-25,-500>,<0,-25,-475>,15 pigment { White }}
>         cylinder {<0,-25, 500>,<0,-25, 475>,15 pigment { White }}
>         cylinder {<0,-25,-450>,<0,-25,450>,20 pigment { White } #if
> ( WorkshopLights ) finish { ambient 10 } #else finish { Shiny } #end
> no_shadow }
>         cylinder {<0,-25,-450>,<0,-25,-475>,17.5 pigment { P_Brass5 }}
>         cylinder {<0,-25, 450>,<0,-25, 475>,17.5 pigment { P_Brass5 }}
> 
> // this is a lil something I used then for testing purposes but I can't
> honestly say what or how anymore
> 
>         #if ( SpeedLighting )
>                 #local Multiplicator = 7/2;
>         #else
>                 #local Multiplicator = 1;
>         #end
> // +++++++++
>         #if (WorkshopLights)
>                 #if (OnOff)
>                         #local C=-Lights;
>                         #while (C<=Lights)
>                         light_source{ 0 color rgb (Multiplicator *
>                         Strength / (Lights * 2 + 1))
>                                 fade_power 1.00 fade_distance 300 //1.35
>                                 translate <0, -25, C*(900/(Lights * 2 +
>                                 1)) > }
>                                 #local C=C+1;
>                         #end
>                 #end
>         #end
> }
> #end
> 
> // Use as
> 
> #declare WorkShopLighting =
> union {
>         object { TL_Bak(on) translate <-2070, 2400,4200 >}
>         object { TL_Bak(on) translate < 2070, 2400,4200 >}
>         object { TL_Bak(on) translate <-2070, 2400,2800 >}
>         object { TL_Bak(on) translate < 2070, 2400,2800 >}
>         object { TL_Bak(on) translate <-2070, 2400,1400 >}
>         object { TL_Bak(on) translate < 2070, 2400,1400 >}
>         object { TL_Bak(on) translate <-2070, 2400,   0 >}
> 
>         object { TL_Bak(on) translate < 2070, 2400,   0 >}
>         object { TL_Bak(on) translate <-2070, 2400,-1400 >}
>         object { TL_Bak(on) translate < 2070, 2400,-1400 >}
>         object { TL_Bak(on) translate <-2070, 2400,-2800 >}
>         object { TL_Bak(on) translate < 2070, 2400,-2800 >}
>         object { TL_Bak(on) translate <-2070, 2400,-4200 >}
>         object { TL_Bak(on) translate < 2070, 2400,-4200 >}
> }
> 
> Feel free to use/mangle/experiment
> 

Check p.b.i for an example image (workshop)
-- 
Ger

Post a reply to this message