"Ard" <ard### [at] waikatoacnz> wrote in message 
news:web.42bbf552bd7481d397d402360@news.povray.org...
>
>> web.42b69f52a6ab8cf34f17dd8d0@news.povray.org
>
> Thanks for that.  However I'm not sure that my problem is the same as
> Burki's, or at least the solution isn't the same.  He had artefacts in
> conical spotlights; I'm getting them at the origin of cylindrical
> spotlights, the beams of which travel only a couple of units before
> striking an object.  It looks like the light is emanating from a black
> saucer.
>
> I have limited the media thus:
>
> box {-2 2
>  hollow pigment{rgbt 1}
>  interior {media { scattering { 2, rgb 1/2 extinction 0} samples 50}}
> }
>
> ....with no improvement.
>
> Thanks for your help so far.  I wonder if I could trouble you for some 
> more
> :-)

Hello,

After futzing around with it here, unfortunately I haven't come to a 
solution either.  I have found however that it does appear to be a 
media-related problem, but as you say, is not the same as Burki's.

I think I must have done much the same experiement with media as you --  
encase the scene and media inside a hollow object to eliminate infinite rays 
as a cause.  Bumping up samples and intervals also made no difference to the 
black circles.

I added looks_like {disc {}} clauses to the light sources to give them 
visibility as physical objects.  The discs are oriented in the direction of 
the beams, representing the front lens/filter of the light  (see code 
below).

What leads me to still suspect it is media, is this:  When the interior 
{media{...}} line is commented out, the cylinder lights now properly look 
like red and blue circles, due to the discs.  They were invisible before. 
Woohoo, progress, etc.  That multiplier of 0.001 I put on on the disc 
location in the pointing direction, is merely to avoid coincident surface 
speckle with the light origin, otherwise its value would have been <0,0,0>.

BUT when the interior {media{...}} line is re-enabled, the lights become 
black holes again.  It seems as though media is not calculated at all for 
rays traced from the camera that hit a light source object(?)  But I'm not 
sure if that really explains why the discs (which are very slightly in front 
of the light origins) also disappear when media is active.  Look closely, 
and you'll see that the part of the disc which is WIDER than the radius of 
the light, is still visible around the black part.

I've pushed your "furniture" around a bit - everything is not where you last 
left it!   :-)
Sorry I haven't been more help than just finding out "more" about the 
problem!

Cheers,
  Brian

---- code ----
camera {
//  location <0, 0.5, -1> look_at y/3
  location <0, 0.5, -2> look_at y/3

}
plane {-z, -1 pigment {rgb 1}}   // Backdrop
plane { y,  0 pigment {rgb 1}}   // Floor
sphere
{ 0, 10 hollow
//  interior {media { scattering { 2, rgb 1/2 extinction 0} intervals 1 
samples 50 }}
}

#declare Light_Location_Red  = <0.1, 0.6, 0.5>;
#declare Light_PointAt_Red   = <-0.05, 0.15, -0.75>; // <-0.05, 0.35, -1>;
#declare Light_Direction_Red = vnormalize (Light_PointAt_Red - 
Light_Location_Red);

#declare Light_Location_Blue  = <-0.5, 0.4, 0>;
#declare Light_PointAt_Blue   = <0.3, 0, -0.1>;
#declare Light_Direction_Blue = vnormalize (Light_PointAt_Blue - 
Light_Location_Blue);


// Illuminate the background so that the black discs at the ends
// off the cylindrical lights are more obvious
light_source {<10, 10 -10> rgb 0.3}
// Blue light on left, aimed right, striking the floor:
light_source {
  Light_Location_Blue
  color rgb <0, 0, 5>
  cylinder
  parallel
  radius 0.05
  falloff 0.10
  point_at Light_PointAt_Blue
  looks_like
  { disc
    { Light_Direction_Blue*0.001, Light_Direction_Blue, 0.11
      pigment {rgb 1} double_illuminate // finish {ambient 1}
    }
  }

}
// Red light aimed nearly at the camera
light_source {
  Light_Location_Red
  color rgb <5, 0, 0>
  cylinder
  radius 0.03
  falloff 0.07
  point_at Light_PointAt_Red
  looks_like
  { disc
    { Light_Direction_Red*0.001, Light_Direction_Red, 0.11
      pigment {rgb 1} double_illuminate //finish {ambient 1}
    }
  }

}

Post a reply to this message