"Barehunter" <nomail@nomail> wrote in message
news:web.4208c6ecc912829bed3cff5c0@news.povray.org...
> I am putting the finishing touches on a picture of the bedroom of the
> character Tuzedo Mask from Sailor moon. MY daughter pointed out to me that
> he always has roses. I was wondering if anyone had a quick rose that I can
> throw in?

Depending on the detail you need, a quick-n-dirty rose (as used in
http://www.tomandlu.co.uk/webres/raytracing/gallery/pics/tmworsh.jpg):

#version 3.6;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <0.0, 0.0, -20.0>
  look_at   <0.0, 0.0,  0.0>
}


light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------

#macro MakeRose(mySeed)
  #declare Count = 1;
 #declare Rand1 = seed(mySeed);

 #declare One_Petal =
 intersection{
   difference{
     sphere{<-1,0,0>, 1.00}
     sphere{<-1,0,0>, 0.98}
   }
   sphere{0,0.5}
   translate y*0.5
   translate x*0.1
 }

  union{
    #while(Count <= 35)
      object{
        One_Petal
        #declare n = rand(Rand1);
        scale <1,1,( 0.25 + (Count/35) + n/4 )>
        #declare n = rand(Rand1);
        rotate x*( (n*10)-5 )
        #declare n = rand(Rand1);
        rotate z*( - ( (sqrt(Count*8)) + (40*n) ) )
        #declare n = rand(Rand1);
        rotate y*( Count*(35 + (35*n)) )
      }
      #declare Count = Count + 1;
    #end
    sphere{0, 0.2}
    rotate x*-90
    scale 2
  }
#end


object{
 MakeRose(32423)
 pigment{Red}
}

object{
 MakeRose(74556)
 pigment{Red}
 translate x*-5
}

object{
 MakeRose(11643)
 pigment{Red}
 translate x*5
}

Post a reply to this message