mienai[AT]hotmail.com wrote:
> I'm trying to get a kind of plastic look for some of my materials, ie where
> everything reflected in sort of blurry.  Generally the blurryness should
> increase the farther the object is from the reflecting surface.  Any ideas?

This may be what you want. Pay special attention to camera blur settings 
  and the normal:

default { finish { ambient 0 } }

global_settings
{
    assumed_gamma 1
}



camera {
     location <0,.5,-5>
     look_at 0
     blur_samples 500//000//131072
     aperture .02
     variance 1/384
     confidence 0.9
     focal_point <-2,0,-1.2>
     }
light_source { <0, 2, -100> rgb 1 }
light_source { <-100, 100, -100> rgb 2.5 }

//sky_sphere { pigment { color rgb <0.2, 0.5, 0.9> } }

plane { y, -1 texture {
         pigment { checker
             rgb <0.02, 0.05, 0.4>*2
             rgb <0.02, 0.05, 0.4>*0.5
         }

     }
     interior { ior 1.33 }
}


#declare textured = normal
{
  spotted 1 scale .001
}

sphere { 0,10000 pigment { rgb 1 } finish { diffuse 0 ambient 1 }  hollow }

sphere { <3,0,4>,1 pigment {color rgb <0.01,0.1,0.7>*1} finish { diffuse 
0.7 specular .7 roughness 0.0005 reflection {0.1,1 fresnel } 
conserve_energy } interior { ior 1.33 } normal { textured }}
sphere { <-2,0,0>,1 pigment {color rgb <1,0.1,0.05>*1} finish { diffuse 
0.7 specular .7 roughness 0.0005 reflection {0.1,1 fresnel } 
conserve_energy } interior { ior 1.33 } normal { textured }}
sphere { <1,0,10>,1 pigment {color rgb <0.01,0.5,0.2>*.25} finish { 
diffuse 0.7 specular .7 roughness 0.0005 reflection {0.1,1 fresnel } 
conserve_energy } interior { ior 1.33 } normal { textured }}


-- 
~Mike

Post a reply to this message