|
|
Vojtech Spiwok <spi### [at] vschtcz> wrote:
> I would like to render a picture of object (protein)
> with a depth cueing. Simple z-oriented ground fog does
> not work because if the fog distance is too small the
> picture is almost white and when it is large there is
> almost no depth-cueing efect.
How about this?
camera { location -z*8 look_at 0 angle 35 }
light_source { <100,150,-400>, 1 }
fog
{ rgb <1,1,1>
fog_type 2
distance .1
fog_offset -.5
fog_alt .2
up -z
}
union
{ sphere { <-1,-1,-1>, .2 }
sphere { <-1,-1, 1>, .2 }
sphere { <-1, 1,-1>, .2 }
sphere { <-1, 1, 1>, .2 }
sphere { < 1,-1,-1>, .2 }
sphere { < 1,-1, 1>, .2 }
sphere { < 1, 1,-1>, .2 }
sphere { < 1, 1, 1>, .2 }
cylinder { <-1,-1,-1>,<-1,-1, 1>, .1 }
cylinder { < 1,-1,-1>,< 1,-1, 1>, .1 }
cylinder { < 1, 1,-1>,< 1, 1, 1>, .1 }
cylinder { <-1, 1,-1>,<-1, 1, 1>, .1 }
cylinder { <-1,-1,-1>,<-1, 1,-1>, .1 }
cylinder { < 1,-1, 1>,< 1, 1, 1>, .1 }
cylinder { < 1,-1,-1>,< 1, 1,-1>, .1 }
cylinder { <-1,-1, 1>,<-1, 1, 1>, .1 }
cylinder { <-1,-1,-1>,< 1,-1,-1>, .1 }
cylinder { <-1, 1, 1>,< 1, 1, 1>, .1 }
cylinder { <-1,-1, 1>,< 1,-1, 1>, .1 }
cylinder { <-1, 1,-1>,< 1, 1,-1>, .1 }
pigment { rgb x } finish { specular .5 }
rotate <-60, -30, 0>
}
Post a reply to this message
|
|