As I was helping out Josh in povray.general with his "Object Pattern in
Media" question, I noticed a strange behavior with media method 3 and shadow
rays.

This media has the following sample parameters:

   method 3
   intervals 1
   samples 3
   aa_level 20

The intended behavior is that 3 samples should be taken, and then more
samples between them if they differ. This produces a very smooth result as
you can see in the image, with only a few artifacts near the edges of the
density shape.

The strange thing is that the shadow is not smooth. Neither the shadow on
the ground nor the self-shadowing of the media is smooth. It appears that
the recursive sampling is not happening for shadow rays! You can see that
there are only 4 levels of brightness on the ground, probably corresponding
to the amount of the 3 samples which are taken that have density.

Is this intended behavior? Although it may be convenient sometimes for
shadow rays to have less accuracy, there should be a way to specify how
accurate they should be, shouldn't there?

This is the scene code for anyone who wants to try this out themself:


#include "colors.inc"

camera {
 location  <0, 5, -40>*.8
 look_at   <0, 0,  0>
}

light_source {<-200, 1000, -400> White}

plane {
 y, -20
 pigment { color rgb <.8,.5,.5> }
}


#declare myObject = union {
 cylinder {
  <8,0,0>,
  <-8,0,0>,
  3
 }
 sphere {
  <0,0,0>
  ,5
 }
}

sphere {
 <0,0,0>,
 10
 texture { pigment { Clear } }
 interior {
  media   {
   scattering {1, 0.1}
   method 3
   intervals 1
   samples 3
   aa_level 20
   density {
    pigment_pattern {object {myObject 0, 1}}
    color_map {[0 rgb 0][1 rgb 1]}
   }
  }
 }
 hollow
}


 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message

Attachments:
Download 'temp.jpg' (21 KB)

Preview of image 'temp.jpg'