"Matthew Pace" <mat### [at] earthlinknet> wrote in message
news:matthewpace-9E3040.22433104022004@news.povray.org...
>    I am tired, and have been rendering this image every moment I get for
> the past few nights (very very little sleep lately).  I basically want a
> box, dark, with glowing strips on it, reflected below it.  I currently
> have the box glowing, but it is insufficient.   The lines emit light,
> sure enough, but there is no glow to them, so I added a sphere to the
> scene, with media in it (looking back now, I realize I could/should have
> used atmospheric media, but that should not effect the outcome.  The
> media does not show up at all, I have played with densities, types (mie
> haze, mie murkey, and type 1- whichever that was).  Yes, media is on in
> the radiosity block, but I cannot get my media to show up.  The
> reflection below the cube is darker, but I think this is more from the
> dark reflective surface and the fact that it is blurred.

I had trouble with the atmosphere so this file didn't do the trick, yet it
might get you closer. The challenge is that even though you can push the
ambience of an object past 1, it does not actually emit light. To an object
emit light, use the looks_like in a light_source object. Example follows
(please don't be offended at the re-write... that was just for my own
understanding of how you made the object):


#include "colors.inc"


/*
global_settings
{
   radiosity
   {
      pretrace_start 0.08
      pretrace_end   0.04
      count 35
      nearest_count 5
      error_bound .8
      recursion_limit 4
      low_error_factor .5
      gray_threshold 0.0
      minimum_reuse 0.015
      brightness 2
      adc_bailout 0.01/2
         media on
    }
}
*/



#local MyOrange= color rgbf <.78,.55,.12,.4> ;
#local CyRadius=.1;


camera
{
   location <7,6,7>
   look_at <0, 0, 0>

   up y
   right image_width / image_height * x
}




light_source
{
   <3,5,6>
   color rgb 0.005
}



/*
media
{
 absorption .5
 emission <.2,.2,.05>

 scattering
 {
  3
  color rgb 1
 }

 density
 {
  bozo

  color_map
  {
   [0 color rgb 0]
   [.5 color rgb 0]
   [1 color rgb 1]
  }
 }
}
*/








plane
{
 y, -0.25

 texture
 {
  average texture_map
  {
   #declare K = 0;
   #declare S = seed(17);
   #while(K < 20)
   [1
      pigment { color rgb 0 }
      finish { reflection 0.8 metallic 0.6 }
      normal
      {
          bumps .05
          translate <rand(S)*1.5,rand(S)*2,rand(S)>*15
          scale 1000
      }
   ]
   #declare K = K+1;
   #end
  }
 }
}






#declare rod =
light_source
{
 0
 color MyOrange

 looks_like
 {
  cylinder
  {
   <0,-2.1,0>, <0, 2.1, 0>, CyRadius


   pigment
   {
    color MyOrange
   }


   finish
   {
    ambient 2
   }
  }
 }
}



sphere
{
 <0, 0, 0>, 1
 translate 3*z

 pigment { color White }
}




#declare face =
union
{
 object { rod translate -0.75*x }
 object { rod translate 0.75*x  }
 object { rod rotate 90*z translate 0.75*y }
 object { rod rotate 90*z translate -0.75*y }
}




#declare puzzlebox =
difference
{
 box
 {
  <-2, -2, -2>, <2, 2, 2>

  pigment
  {
    color rgb <0.3, 0.3, 0.3>
  }

  finish
  {
   reflection 0.5
  }
 }

 object { face translate -2*z }
 object { face translate 2*z }

 object { face rotate 90*y translate -2*x }
 object { face rotate 90*y translate 2*x }

 object { face rotate 90*x translate 2*y }
 object { face rotate 90*x translate -2*y }
}



object { puzzlebox translate 1.5*y }

Post a reply to this message