"Brent G" <pov### [at] bc-hqcom> wrote in message
news:3f945faa@news.povray.org...
> See my pic in p.b.images.

The merge of the plane and box is causing the difference to be ignored for
the lower part of the "center" cut away box. Although I'm not certain why
the appearance manifests itself in the way it does.

Shadowing needs a light-diffusing surface or subsurface, so to get one for
the water you'll either need to raise diffuse or add scattering to the
media. BTW, you forgot 'hollow' for the water box.

Here's a working example.

difference {
           //Grass
           plane{<0,1,0>, 0
                 texture {
                         pigment {
                                 dents
                                 triangle_wave
                                  color_map {
                                         [0.0 rgb <0.0, 0.4, 0.1>]
                                         [1.0 rgb <0.1, 0.6, 0.2>]
                                 }
                         }
                 }
         }
         //Big Box
         box { <-10, -.7,-0.5> <10, .5, 200.5>
          texture{ pigment {rgb <1,0,0>}
           normal {bumps 0.75 scale 0.015}
           finish {ambient 0.1 diffuse 0.8} }}
 }

difference {
        //Big Box
        box { <-10, -.7,-0.5> <10, .5, 200.5>
         texture{ pigment {rgb <0,0,1>}
          normal {bumps 0.75 scale 0.015}
          finish {ambient 0.1 diffuse 0.8} }}
        //Center Cutout
        box { <-9, -.6, 0> <9,  .8, 200>
         texture{ pigment {rgb <1,1,0>}
          normal {bumps 0.75 scale 0.015}
          finish {ambient 0.1 diffuse 0.8} }}
}

//Water Area
box {
  <-9, -0.6, 0.001> <9,  0.4, 199.9>
  material {
    texture {
      pigment { color rgbf <0.2, 0.7, 0.3, 0.5> }
      finish {
        ambient color rgb <0, 0, 0>
        diffuse 0
        reflection {
          0.0, 1.0
          fresnel on
        }
        specular 0.8
        roughness 0.0003
      }
      normal {
        bozo 0.7
        scale 0.15
      }
    }
    interior {
      ior 1.3
      media { absorption <0.8, 0.6, 1.0> // filter value wasn't needed here
        scattering {2,10} density {rgb 10} // example for visible shadow
(extreme, yeah)
        }
    }
  }
  hollow
}

sphere {<5,5,5>,3 pigment {rgb 1}} // shadow maker

// END

Hopefully there's still an explanation about the odd missing corners of a
merging plane and box but it eludes me at the moment. Too bad this other way
isn't as short.
-- 
Bob H.
http://www.3digitaleyes.com

Post a reply to this message